Sumifs 与 OR AND

Question

我有一个看起来像这样的数据集...

Group   Opportunity   Close Date    Stage   Yr Credited Probability Adjusted Credit
    Sigma   A           12/31/2016  Lost    2016          0.1
    Alpha   B           1/1/2016    Signed  2016          0.5
    Beta    C           7/26/2016   Review  2016          0.7
    Sigma   D - Loss    1/1/2016    Lost    2016          -1
    Alpha   E           12/31/2016  Review  2016          0.7
    Beta    F           1/25/2016   Pending 2016          0.6
    Sigma   G           12/31/2016  Review  2016          0.4
    Alpha   H           4/6/2014    Expired 2015          0.9
    Beta    I           5/14/2015   Pending 2015          0.1
    Sigma   J           12/31/2016  Review  2016          0.7
    Alpha   K - Loss    2/3/2016    Lost    2016          -0.5
    Beta    L           12/31/2016  Expired 2016          0.8
    Sigma   M           1/25/2016   Expired 2016          0.6
    Alpha   N           12/31/2016  Pending 2016          0.5
    Beta    O           12/31/2016  Pending 2016          0.4
    Sigma   P           12/31/2016  Pending 2016          0.3

我的部分目标是为我们提供一个带有 AND 和 OR 语句的 SUMIFS 函数。如果满足以下条件，该公式应产生每个组的概率调整学分总和：阶段 = 审查或两个阶段 = 丢失和机会包含 "Loss"

该公式必须像 SUMIFS 公式一样发挥作用，因为我还有其他要纳入的标准。然而，这部分标准对我来说并不直接。

Answer 1

使用 SUMPRODUCT():

=SUMPRODUCT((($D:$D = "Review")+(($D:$D = "Lost")*(ISNUMBER(SEARCH("Loss",$B:$B))))>0)*($F:$F))

当使用 AND 和 OR 的数组公式时，分别使用操作数 * 和 +。

编辑：

添加分组：

=SUMPRODUCT((($D:$D = "Review")+(($D:$D = "Lost")*(ISNUMBER(SEARCH("Loss",$B:$B))))>0)*($F:$F)*($A:$A=H2))

Answer 2

个别小组的候补 SUMPRODUCT function。

=SUMPRODUCT((A:INDEX(A:A, MATCH("zzz",A:A ))=H2)*
                 SIGN((D:INDEX(D:D, MATCH("zzz",A:A ))="review")+
                 (D:INDEX(D:D, MATCH("zzz",A:A ))="lost")*
                 (RIGHT(B:INDEX(B:B, MATCH("zzz",A:A )), 4)="loss")),
             F:INDEX(F:F, MATCH("zzz",A:A )))

如果可以帮助您理解公式，您可以保留该公式中的换行符。

SUMPRODUCT 函数不能很好地与 AND / OR 函数一起使用。使用 + 表示 OR 和 * 表示 AND 并使用适当的括号来提供层次结构。

Sumifs 与 OR AND

Sumifs with OR AND

excel

sum

sumifs