Agda 中的排中律

Question

我听说 Agda 的 Martin-Lof 类型理论与排除中间值是一致的。我将如何将其添加为假设？另外，添加LEM之后，是不是经典的一阶逻辑？我的意思是，我是否也有 not (for all) = there exist (not) 等价？本人不懂类型论，如有引用类型论结果请补充说明

Answer 1

在MLTT中，exists对应于标准库中Data.Product中定义的依赖对。它将存在见证和它拥有权利的证明打包在一起属性.

不需要假设任何东西来证明存在命题的否定蕴含被否定的全称命题属性:

∄⇒∀ : {A : Set} {B : A → Set} →
      ¬ (∃ λ a → B a) →
      ∀ a → ¬ (B a)
∄⇒∀ ¬∃ a b = ¬∃ (a , b)

然而，为了证明相反的情况，你确实需要排中律来让证人凭空出现。用新的假设扩展 Agda 真的很容易，你可以简单地写 (Dec is defined in Relation.Nullary):

postulate LEM : (A : Set) → Dec A

记住如何从 LEM 开始证明双重否定消除总是一件好事，无论如何我们稍后都会需要它（case_of_ 定义在 Function and explained in README.Case):

¬¬A⇒A : {A : Set} → ¬ (¬ A) → A
¬¬A⇒A {A} ¬¬p =
  case LEM A of λ
    { (yes p) → p
    ; (no ¬p) → ⊥-elim $ ¬¬p ¬p
    }

然后你可以证明全称命题的否定蕴涵了一个像这样的存在主义：

¬∀⇒∃ : {A : Set} {B : A → Set} →
      ¬ (∀ a → B a) →
      ∃ λ a → ¬ (B a)
¬∀⇒∃ {A} {B} ¬∀ = 
  case LEM (∃ λ a → ¬ B a) of λ
    { (yes p) → p
    ; (no ¬p) → ⊥-elim $ ¬∀ (¬¬A⇒A ∘ ∄⇒∀ ¬p)
    }

A gist with all the right imports

Agda 中的排中律

Law of excluded middle in Agda

logic

agda

type-theory