是否可以在派生 Generic 的记录数据类型中列出字段的名称和类型？

Question

我知道对于派生 Data.Data 的数据类型，constrFields 给出字段名称列表。查看 GHC.Generics 文档，我认为 Generic 也应该可以做到这一点。（但不幸的是我自己没有弄清楚该怎么做）。

更具体地说，我正在寻找两件事：

列出所有记录字段

... 在 Haskell 程序中。我知道 aeson 能够自动推断派生 Generic 的任何记录数据类型的 JSON 表示，但阅读其源代码只能证实我在这里一无所知。据我猜测，aeson 必须能够从记录数据类型中获取所有字段名称（如 Strings 或 ByteStrings）以及它们的类型（具有类似Data.Typeable 中的 TypeRep 或 Eq 的实例：任何可用于 case 块模式匹配的东西都可以。

我模糊地假设为 M1、:*: 等创建 class 和实例是正确的方法，但我无法进入类型检查器。

检查记录选择器

获取其所属的记录数据类型，记录字段名（如String）等

例如给定

data Record = Record
    { recordId :: Int32
    , recordName :: ByteString
    } deriving Generic

一个类似于

的函数magic

typeOf (Record {}) == typeOf (magic recordId)

这些可以用 deriving Generic 实现吗，还是我必须求助于模板 Haskell？

Answer 1

列出所有记录字段

这个很有可能，它确实是通过使用 class 在 Rep 的结构上递归完成的。下面的解决方案适用于单构造函数类型和 return 没有选择器的字段的空字符串名称：

{-# LANGUAGE DeriveGeneric #-}
{-# LANGUAGE PolyKinds #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE ScopedTypeVariables #-}

import Data.ByteString (ByteString)
import Data.Data
import Data.Int
import Data.Proxy
import GHC.Generics
import qualified Data.ByteString as B

data Record = Record { recordId :: Int32, recordName :: ByteString }
  deriving (Generic)

class Selectors rep where
  selectors :: Proxy rep -> [(String, TypeRep)]

instance Selectors f => Selectors (M1 D x f) where
  selectors _ = selectors (Proxy :: Proxy f)

instance Selectors f => Selectors (M1 C x f) where
  selectors _ = selectors (Proxy :: Proxy f)

instance (Selector s, Typeable t) => Selectors (M1 S s (K1 R t)) where
  selectors _ =
    [ ( selName (undefined :: M1 S s (K1 R t) ()) , typeOf (undefined :: t) ) ]

instance (Selectors a, Selectors b) => Selectors (a :*: b) where
  selectors _ = selectors (Proxy :: Proxy a) ++ selectors (Proxy :: Proxy b)

instance Selectors U1 where
  selectors _ = []

现在我们可以拥有：

selectors (Proxy :: Proxy (Rep Record))
-- [("recordId",Int32),("recordName",ByteString)]

这里最不明显的部分是 selName 和 Selector：这个 class 可以在 GHC.Generics 中找到，它允许我们从生成的选择器类型。在Record的情况下，表示为

:kind! Rep Record
Rep Record :: * -> *
= D1
    Main.D1Record
    (C1
       Main.C1_0Record
       (S1 Main.S1_0_0Record (Rec0 Int32)
        :*: S1 Main.S1_0_1Record (Rec0 ByteString)))

选择器类型为Main.S1_0_0Record和Main.S1_0_1Record。我们只能通过使用 classes 或类型族从 Rep 类型中提取它们来访问这些类型，因为 GHC 不会导出它们。无论如何，selName 从任何带有 s 选择器标签的 M1 节点获取选择器名称（它有一个更通用的类型 t s f a -> String 但这与我们无关） .

也可以处理多个构造函数，有selectorsreturn[[(String, TypeRep)]]。在那种情况下，我们可能会有两个 class es，一个类似于上面的，用于从给定的构造函数中提取选择器，另一个 class 用于收集构造函数的列表。

检查记录选择器

通过函数获取记录类型很容易：

class Magic f where
  magic :: f -> TypeRep

instance Typeable a => Magic (a -> b) where
  magic _ = typeOf (undefined :: a)

或静态：

type family Arg f where
   Arg (a -> b) = a

然而，如果没有 TH，我们无法知道一个函数是合法的选择器还是只是一个具有正确类型的函数；它们在 Haskell 中无法区分。无法检查 magic recordId 中的名称 "recordId"。

2019 更新：使用 GHC 8.6.5 提取选择器并键入 TypeReps。我们通过摆脱代理以支持类型应用程序来使解决方案更加现代化。

{-# language
  AllowAmbiguousTypes,
  DeriveGeneric,
  FlexibleContexts,
  FlexibleInstances,
  RankNTypes,
  TypeApplications,
  TypeInType
  #-}

import Type.Reflection
import GHC.Generics

class Selectors rep where
  selectors :: [(String, SomeTypeRep)]

instance Selectors f => Selectors (M1 D x f) where
  selectors = selectors @f

instance Selectors f => Selectors (M1 C x f) where
  selectors = selectors @f

instance (Selector s, Typeable t) => Selectors (M1 S s (K1 R t)) where
  selectors =
    [(selName (undefined :: M1 S s (K1 R t) ()) , SomeTypeRep (typeRep @t))]

instance (Selectors a, Selectors b) => Selectors (a :*: b) where
  selectors = selectors @a ++ selectors @b

instance Selectors U1 where
  selectors = []

现在用法变为 selectors @(Rep MyType)。

是否可以在派生 Generic 的记录数据类型中列出字段的名称和类型？

Is it possible to list the names and types of fields in a record data type that derives Generic?

generics

haskell

type-systems

aeson

列出所有记录字段

检查记录选择器

列出所有记录字段

检查记录选择器