Stage.RESIZE : 是否可以在浏览器中 运行 这个例子？

Question

是否可以在浏览器中 运行 这个简单的代码？ 在 .swf 中似乎一切正常，但我无法在浏览器中调整 .swf 的大小... 舞台未在 HTML 页面中调整大小。 通过 .swf 文件，它就像一个魅力。 有人对这个问题有想法吗？

package com{
    import flash.display.Graphics;
    import flash.display.MovieClip;
    import flash.display.Stage;
    import flash.display.StageAlign;
    import flash.display.StageQuality;
    import flash.display.StageScaleMode;
    import flash.events.Event;
    import flash.text.TextField;

public class Main extends MovieClip{
    private static const ORANGE:int = 0xff9900;
    var bg:MovieClip;
    var bg_mask:MovieClip;
    var marginx:int = 10;
    var marginy:int = 10;
    var display:MovieClip;
    var displayTextField:TextField;
    var ellipseWidth:int = 90;
    var ellipseHeight:int = 90;
    public function Main(){
        super();
        bg = new MovieClip();
        bg_mask = new MovieClip();
        display = new MovieClip();
        displayTextField = new TextField();
        this.addChild(bg);
        this.addChild(bg_mask);
        this.addChild(display);
        this.display.addChild(displayTextField);
        displayTextField.text = "";
        displayTextField.x = ellipseWidth/Math.PI;
        displayTextField.y = ellipseHeight/Math.PI;
        stage.align = StageAlign.TOP_LEFT;  // or StageAlign.TOP
        stage.scaleMode = StageScaleMode.NO_SCALE;
        drawBackground();
        display.mask = bg_mask;
        addListeners();
    }
    private function drawBackground(thickness:int=1,lineColor:int=0x000000,lineAlpha:Number=0.5,fillColor:int=ORANGE,fillAlpha:Number=0.5):void{
        var g:Graphics = bg.graphics;
        g.clear();
        g.lineStyle(thickness,lineColor,lineAlpha);
        g.beginFill(fillColor,fillAlpha);
        g.drawRoundRect(marginx,marginy,this.stage.stageWidth-marginx*2,this.stage.stageHeight-marginy*2,ellipseWidth,ellipseHeight);
        g.endFill();
    }
    private function drawMask():void{
        var g:Graphics = bg_mask.graphics;
        g.clear();
        g.lineStyle(1,0x000000,0.3);
        g.beginFill(0xcccccc,0.1);
        g.drawRoundRect(marginx,marginy,this.stage.stageWidth-marginx*2,this.stage.stageHeight-marginy*2,90,90);
        g.endFill();
    }
    private function addListeners():void{
        stage.addEventListener(Event.ADDED,updateLabel);
        stage.addEventListener(Event.RESIZE,updateLabel);
    }
    private function updateLabel(e:Event):void{
        updateDisplay();
        drawBackground();
        drawMask();
    }
    private function updateDisplay():void{
        var tf:TextField = displayTextField;
        tf.text = ("{" + this.stage.stageWidth + ";" + this.stage.stageHeight + "}");
    }
}

}

Answer 1

在在线上下文中，flash 文档包含在 HTML parent 元素 (object/embed) 中。

您的 AS3 代码控制如何在该元素中显示您的 Flash 内容。它不知道容器以外的任何东西。

您的问题很可能是 HTML 容器。如果它具有固定大小，那么无论您在 AS3 中做什么，它都不会超出其容器范围。

尝试为您的 HTML 容器提供可变尺寸（例如 100% 宽度，100% 高度）以及任何 grandparent html 元素，使您的尺寸调整更具动态性。