如何从管道 (jenkinsfile) 中使用 Jenkins Copy Artifacts 插件？

Question

我正在尝试从 Jenkins 管道（工作流）中查找使用 Jenkins Copy Artifacts 插件的示例。

任何人都可以指出使用它的示例 Groovy 代码吗？

Answer 1

如果你在你的主人中使用奴隶并且你想在彼此之间复制工件你可以使用stash/unstash，例如：

stage 'build'
node{
   git 'https://github.com/cloudbees/todo-api.git'
   stash includes: 'pom.xml', name: 'pom'
}

stage name: 'test', concurrency: 3
node {
   unstash 'pom'
   sh 'cat pom.xml' 
}

你可以在这个link中看到这个例子：

https://dzone.com/refcardz/continuous-delivery-with-jenkins-workflow

Answer 2

name = "/" + "${env.JOB_NAME}"
def archiveName = 'relNum'
try {
    step($class: 'hudson.plugins.copyartifact.CopyArtifact', projectName: name, filter: archiveName)
} catch (none) {
    echo 'No artifact to copy from ' + name + ' with name relNum'
    writeFile file: archiveName, text: '3'
}

def content = readFile(archiveName).trim()
echo 'value archived: ' + content

尝试使用复制工件插件

Answer 3

如果构建不在同一管道中运行您可以使用直接 CopyArtifact 插件，这里是示例：https://www.cloudbees.com/blog/copying-artifacts-between-builds-jenkins-workflow 和示例代码：

node {
   // setup env..
   // copy the deployment unit from another Job...
   step ([$class: 'CopyArtifact',
          projectName: 'webapp_build',
          filter: 'target/orders.war']);
   // deploy 'target/orders.war' to an app host
}

Answer 4

使用声明性 Jenkinsfile，您可以使用以下管道：

pipeline {
    agent any
    stages {
        stage ('push artifact') {
            steps {
                sh 'mkdir archive'
                sh 'echo test > archive/test.txt'
                zip zipFile: 'test.zip', archive: false, dir: 'archive'
                archiveArtifacts artifacts: 'test.zip', fingerprint: true
            }
        }

        stage('pull artifact') {
            steps {
                copyArtifacts filter: 'test.zip', fingerprintArtifacts: true, projectName: env.JOB_NAME, selector: specific(env.BUILD_NUMBER)
                unzip zipFile: 'test.zip', dir: './archive_new'
                sh 'cat archive_new/test.txt'
            }
        }
    }
}

在 CopyArtifact 1.39 版本之前，您必须将第二阶段替换为以下内容（感谢@Yeroc）：

stage('pull artifact') {
    steps {
        step([  $class: 'CopyArtifact',
                filter: 'test.zip',
                fingerprintArtifacts: true,
                projectName: '${JOB_NAME}',
                selector: [$class: 'SpecificBuildSelector', buildNumber: '${BUILD_NUMBER}']
        ])
        unzip zipFile: 'test.zip', dir: './archive_new'
        sh 'cat archive_new/test.txt'
    }
}

对于 CopyArtifact，我使用“${JOB_NAME}”作为当前运行项目的项目名称。

CopyArtifact 使用的默认选择器使用上次成功的项目构建号，而不是当前的（因为它尚未成功，或未成功）。使用 SpecificBuildSelector，您可以选择“${BUILD_NUMBER}”，其中包含当前运行项目构建号。

此管道与并行阶段一起工作并且可以管理大文件（我使用的是 300Mb 文件，它不适用于 stash/unstash）

This pipeline works perfectly with my Jenkins 2.74, provided you have all needed plugins

如何从管道 (jenkinsfile) 中使用 Jenkins Copy Artifacts 插件？

How can I use the Jenkins Copy Artifacts Plugin from within the pipelines (jenkinsfile)?

groovy

jenkins-workflow

jenkinsfile