使用 gnuplot，如何 'cut out' 使用图形的 y 轴区域

Question

我正在尝试绘制图表，其中 Y 轴上有 CPU 利用率，当前范围是 0-100%。我的数据仅由 0-20% 和 80-100% 组成，而且我只有 20-80% 的大白色间隙。有什么方法可以 'cut out' 这个空白 space，让观众可以更详细地看到在 0-20% 和 80-100% 范围内发生了什么？

谢谢。

Answer 1

正如 Christoph 在评论中所说，这需要使用 set multiplot 和删除边框等手动完成。例如：

set multiplot
# remove border and ytics from right hand side
set border 7
set ytics nomirror
# set top and bottom margins for both halves of the plot
set tmargin at screen 0.96
set bmargin at screen 0.1
# set left and right margins for left half of the plot
set lmargin at screen 0.1
set rmargin at screen 0.5
# set xrange for left half of the plot
set xrange [0:2*pi]
# set some lines to delimit transition from one half of the plot to next
set arrow from screen 0.50,0.08 to screen 0.52,0.12 nohead
set arrow from screen 0.49,0.08 to screen 0.51,0.12 nohead
set arrow from screen 0.50,0.94 to screen 0.52,0.98 nohead
set arrow from screen 0.49,0.94 to screen 0.51,0.98 nohead
# plot left half
plot sin(x) not
# remove border from left hand side and set ytics on the right
set border 13
unset ytics
set y2tics
set format y2 ""
# set left and right margins for right half of the plot
set lmargin at screen 0.51
set rmargin at screen 0.91
# set xrange for right half of the plot
set xrange [13.5:13.5+2*pi]
# plot
plot sin(x) axes x1y2

使用 gnuplot，如何 'cut out' 使用图形的 y 轴区域

Using gnuplot, how to 'cut out' usused y-axis regions of the graph

gnuplot