有没有办法阻止 CL_SALV_TABLE 删除前导空格？

Question

有没有办法防止 CL_SALV_TABLE 的实例删除显示中的前导 space？

我有以下代码，其中我在 Master 文本前面放了一个 space，在 Slave 文本前面放了两个 space。

REPORT zzy.

CLASS lcl_main DEFINITION FINAL CREATE PRIVATE.
  PUBLIC SECTION.
    CLASS-METHODS:
      main.
ENDCLASS.

CLASS lcl_main IMPLEMENTATION.
  METHOD main.
    TYPES: BEGIN OF l_tys_test,
      name  TYPE string,
      value TYPE i,
    END OF l_tys_test,
    l_tyt_test TYPE STANDARD TABLE OF l_tys_test WITH EMPTY KEY.

    DATA(lt_test) = VALUE l_tyt_test(
      ( name = `Root` value = 0 )
      ( name = ` Master` value = 1 )
      ( name = `  Slave` value = 2 )
    ).

    cl_salv_table=>factory(
      IMPORTING
        r_salv_table = DATA(lo_salv_table)
      CHANGING
        t_table = lt_test
    ).
    lo_salv_table->display( ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  lcl_main=>main( ).

不幸的是，领先的 space 在视图中被修剪了。

在这个 tutorial 中，这家伙似乎以某种方式成功了。

Answer 1

是的，有：

lo_salv_table->get_columns( )->get_column( 'NAME' )->set_leading_spaces( abap_true ).

有没有办法阻止 CL_SALV_TABLE 删除前导空格？

Is there a way to prevent CL_SALV_TABLE from removing leading spaces?

abap

alv