Prolog

Question

我无法生成满足特定条件的所有列表。

city(new_york, 47).
city(chicago, 100).

all_unique([]).
all_unique([H|T]) :- H = [] ; (not(member(H, T)), all_unique(T)).

cities([Head|Tail]) :-
    length(Tail, L),
    L < 2,
    city(Head, _A),
    (Tail = [] ; cities(Tail)).

当我发出查询 cities(L) 时，我希望它生成最大长度为 2 且不重复的所有城市列表。它现在所做的是 return 所有可能的列表，然后继续尝试显然不符合条件的列表。

?- cities(L).
L = [new_york] ;
L = [chicago] ;
L = [new_york, new_york] ;
L = [new_york, chicago] ;
L = [chicago, new_york] ;
L = [chicago, chicago] ;
ERROR: Out of global stack
?-

如何告诉 Prolog 不要尝试太长或有重复项的列表？

Answer 1

您对 all_unique/1 的定义更好地基于 prolog-dif:

all_unique([]).
all_unique([E|Es]) :-
   maplist(dif(E), Es),
   all_unique(Es).

基于meta-predicate maplist/2 你可以这样定义cities/1：

city_(new_york, 47).
city_(chicago, 100).

city(C) :-
   city_(C, _).

cities(List) :-
   length(Ref, 2),
   append(List, _, Ref),
   all_unique(List),
   maplist(city, List).

示例查询：

?- cities(Xs).
Xs = [] ;
Xs = [new_york] ;
Xs = [chicago] ;
Xs = [new_york, chicago] ;
Xs = [chicago, new_york] ;
false.                                    % terminates universally

Prolog - 如何限制变量列表长度

Prolog - How to limit variable list length

list

prolog-dif