比较 Squeak Smalltalk 中的块

Question

我在吱吱编程，需要比较两块代码如下：（toRunBlock是一个实例变量）

~~~Other code~~~
toRunBlock := [nil].
~~~Other code~~~

但在某些时候，我需要将它与另一段代码进行比较：

(toRunBlock = [nil]) ifTrue: [
    "Run some code if toRunBlock hasn't been overwritten"
].

但是那个检查总是给出错误，我找不到检查它们是否相等的方法。有人可以帮我解决这个问题吗？

Answer 1

没有为 BlockClosures 定义相等性，引用相等性除外。尽管两个块的行为可能相同，但它们仍然不同，因为它们是闭包，而不仅仅是代码片段。每个块都有对其创建的上下文（方法激活或另一个块）的引用，因此您的两个 [nil] 至少在这方面有所不同。

您只能通过将之前的内容存储在其他地方来检查该块是否仍然与之前相同。假设 [nil] 在您的情况下是某种默认值，您可以将该 [nil] 块存储在另一个实例变量或 class 池变量（例如，defaultRunBlock）中并比较 toRunBlock（通过参考）与该变量一起检查 toRunBlock 是否已更改。

Object subclass: #YourClass
    instanceVariableNames: 'toRunBlock defaultRunBlock' 
        "or as class variable:"
    classVariableNames: 'DefaultRunBlock'
    poolDictionaries: ''
    category: 'Kernel-Methods'

initialize
    defaultRunBlock := [nil]

otherCode
    toRunBlock := defaultRunBlock

whereYouCompareThem
    toRunBlock == defaultRunBlock ifTrue: [ "..." ]

或者，如果您想检查自上次调用后一个方法后 toRunBlock 是否发生了变化，您也可以将先前的值存储在一个额外的实例变量中。

whereYouCompareThem
    toRunBlock == previousRunBlock ifTrue: [ "..." ].
    previousRunBlock := toRunBlock

Answer 2

正如@LeandroCaniglia 指出的那样，您不必比较块。这里有两种无需比较块即可解决问题的方法：

初始化变量为nil。在您的访问器方法中，您懒惰地初始化它：
```
toRunBlock
    ^ toRunBlock ifNil: [ [] ]
```
现在，当您查看变量 toRunBlock 时，它将是 nil 除非 #toRunBlock 已发送或通过其他方式设置了块。

您的代码将变为：
```
toRunBlock ifNil: [
    "Run some code if toRunBlock hasn't been overwritten"
].
```

通过设置您可以检查的实例变量来使用附加状态。这可能是您的 setter 方法，例如：

toRunBlock: aBlock
    toRunBlock := aBlock.
    hasToRunBlockBeenSet := true

要检查您可以使用这样的方法：

hasToRunBlockBeenSet
    ^ hasToRunBlockBeenSet ifNil: [ false ]

您的代码将变为：

self hasToRunBlockBeenSet ifTrue: [
    "Run some code if toRunBlock hasn't been overwritten"
].

第二种方法可以说更可靠。

比较 Squeak Smalltalk 中的块

Comparing Blocks in Squeak Smalltalk

smalltalk

squeak