XSLT：如何从查找 table 中插入数据？

Question

我正在尝试根据将一个 XML 文档中的 id 与查找 XML 文档中的 id 进行匹配并将值插入匹配节点中包含的值来将值插入到属性中。我可以正确地匹配和评估匹配，但我不知道如何将匹配节点的值插入到结果 XML 中。具体来说，我试图获取当前单词编号的值，在与旧编号系统匹配的值列表中查找匹配的 id，并将该值作为属性插入到组合的 XML 文档输出中.如果没有匹配项，它只会将当前的 NO 字段放在那里。

lookup.xml:

<?xml version="1.0" encoding="ISO-8859-1"?>
<mdict>
    <PR id="NEW1">OLD1</PR>
    <PR id="NEW2">OLD2</PR>
    <PR id="NEW3">OLD3</PR>
    <PR id="NEW4">OLD4</PR>
    <PR id="NEW5">OLD5</PR>
    <PR id="NEW6">OLD6</PR>

</mdict>

XML:

<?xml version = "1.0" encoding = "UTF-8"?>
<dictionary>
    <entry><NO>NEW1</NO><PR>phon text1</PR></entry>
    <entry><NO>NEW2</NO><PR>phon text2</PR></entry>
    <entry><NO>NEW3</NO><PR>phon text3</PR></entry>
    <entry><NO>NEW4</NO><PR>phon text4</PR></entry>
    <entry><NO>NEW5</NO><PR>phon text5</PR></entry>
    <entry><NO>NEW6</NO><PR>phon text6</PR></entry>
</dictionary>

XSLT：

?xml version="1.0" encoding="UTF-8"?>
<xsl:transform
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" encoding="utf-8" indent="no"/> 

    <xsl:variable name='prons' select='document("lookup.xml")'/>
    <xsl:key name='pron' match='PR' use='@id' />

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="PR">
        <xsl:param name="curr-pron"/>
            <xsl:choose>
                <xsl:when test="../preceding-sibling::NO/text() = $prons/mdict/PR/@id">
                    <xsl:value-of select="key('pron', $curr-pron)/PR"/>
                    <pr pron="{$curr-pron}"><xsl:apply-templates/></pr>
                </xsl:when>
                <xsl:otherwise>
                    <pr pron="{../preceding-sibling::NO}"><xsl:apply-templates/></pr>
                    </xsl:otherwise>
                </xsl:choose>
    </xsl:template>

期望的输出：

<dictionary>
    <entry><NO>NEW1</NO><pr pron="OLD1">phon text1</pr></entry>
    <entry><NO>NEW2</NO><pr pron="OLD2">phon text2</pr></entry>
    <entry><NO>NEW3</NO><pr pron="OLD3">phon text3</pr></entry>
    <entry><NO>NEW4</NO><pr pron="OLD4">phon text4</pr></entry>
    <entry><NO>NEW5</NO><pr pron="OLD5">phon text5</pr></entry>
    <entry><NO>NEW6</NO><pr pron="OLD6">phon text6</pr></entry>
</dictionary>

谢谢！

Answer 1

我建议你这样试试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="old-pron" match="PR" use="@id" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="PR">
    <xsl:variable name="id" select="../NO" />
    <pr>
        <xsl:attribute name="pron">
        <!-- switch context to use key -->  
            <xsl:for-each select="document('lookup.xml')">
                <xsl:value-of select="key('old-pron', $id)"/>
            </xsl:for-each>
        </xsl:attribute>
        <xsl:apply-templates/>
    </pr>
</xsl:template>

</xsl:stylesheet>

假设您正在处理上面的 XML 文档。

请注意，在 XSLT 1.0 中，键不能跨文档使用。

XSLT：如何从查找 table 中插入数据？

XSLT: How can I insert data from a lookup table?

xml

xslt

param