VB 使用 advapi32.dll cryptverifysignature 的代码适用于 Vista SP2 而不是 Windows 10 64 位

Question

我一直在尝试解决为什么在 Vista SP2 机器上用 VB6 编写和编译的应用程序元素在该机器上运行良好但在 64 位 Windows 10 机器上运行不正常。为了提高调试能力，我在 Excel VBA 中复制了问题编码。适用于 Vista 机器，但不适用于 Windows 10 机器。

CryptoAPI 调用都这样声明：

Private Declare Function CryptVerifySignature _
Lib "advapi32.dll" _
    Alias "CryptVerifySignatureA" ( _
        ByVal hHash As Long, _
        pbSignature As Byte, _
        ByVal dwSigLen As Long, _
        ByVal hPubKey As Long, _
        ByVal sDescription As String, _
        ByVal dwFlags As Long _
            ) As Long

Windows 10 机器上出现故障的部分在下面的火车轨道上方和下方突出显示：

Private Function SignValidate(ByRef abData() As Byte, _
                        ByRef abSigned() As Byte, _
                        Optional bSigned As Boolean = True) As Long
Dim hHash As Long
Dim lngReturnValue As Long
Dim lngSigLen As Long
Dim abText() As Byte
Dim strTxt As String
Dim lngW As Long
Dim lngX As Long
Dim lngY As Long

Dim abHashVal() As Byte

SignValidate = -1
ReDim abText(UBound(abData))
abText = abData

'Create a hash object to sign/validate
lngReturnValue = CryptCreateHash(hCryptProv, CALG_SHA, 0, 0, hHash)
If lngReturnValue = 0 Then
    'Set_locale regionalSymbol
    Err.Raise Err.LastDllError, , "DLL error code shown above. Could not create a Hash Object (CryptCreateHash API)"
End If
'Hash the data
lngW = UBound(abText) + 1
lngReturnValue = CryptHashData(hHash, abText(0), lngW, 0)
If lngReturnValue = 0 Then
    'Set_locale regionalSymbol
    Err.Raise Err.LastDllError, , "DLL error code shown above. Could not calculate a Hash Value (CryptHashData API)"
End If

If bSigned Then
    'release old key pair handle
    If hKeyPair <> 0 Then CryptDestroyKey hKeyPair
    'get a handle to the signature key pair
    lngReturnValue = CryptGetUserKey(hCryptProv, AT_SIGNATURE, hKeyPair)
    If lngReturnValue = 0 Then
        'Set_locale regionalSymbol
        Err.Raise Err.LastDllError, , "DLL error code shown above. Could not obtain key pair"
    End If
    'Determine the size of the signature
    lngReturnValue = CryptSignHash(hHash, AT_SIGNATURE, 0, 0, vbNull, lngSigLength)
    If lngSigLength > 0 Then ReDim abSig(lngSigLength - 1)
    'Sign the hash object
    lngReturnValue = CryptSignHash(hHash, AT_SIGNATURE, 0, 0, abSig(0), lngSigLength)
    If lngReturnValue = 0 Then
        'Set_locale regionalSymbol
        Err.Raise Err.LastDllError, , "DLL error code shown above. Could not sign the hash"
    End If
    ' the signature is now available
    ' size returned array to signature length
    ReDim abSigned(UBound(abSig))
    ' return the signature to the calling procedure
    abSigned = abSig
    SignValidate = 0
Else
    lngSigLength = UBound(abSigned) + 1
    ReDim abSig(UBound(abSigned))
    abSig = abSigned ' load the Signature array

'========================================================
    'this is the line where the actual validation is done
    lngReturnValue = CryptVerifySignature(hHash, abSig(0), lngSigLength, hKeyPair, 0, 0)
'========================================================
    If lngReturnValue = 0 Then 'some error occurred
        SignValidate = Err.LastDllError
    Else
        SignValidate = 0
    End If
End If
End Function

Windows 10 机器在突出显示对 CryptVerifySignature 和 returns Err.LastDllError 等于 NTE_BAD_SIGNATURE 的调用时失败。 Vista 机器验证签名正常。

我花了几天时间研究这里可能发生的事情。都无济于事。任何指点都感激不尽

Answer 1

EDIT - I can't see anything wrong with your declare or call

我见过的唯一选择是将字节指针更改为声明为 ByVal pSignature Long，然后使用 varPtr(abSig(0)

调用它

但是你的代码看起来不错 - 我很困惑

您的声明与 Microsoft API 声明不符。不确定这是否是设计使然，因为 Signature 是一个字节指针

根据文档

LPBYTE, BYTE  will be : *   ByRef Byte

改变这一点（默认参数通过 ByVal）

pbSignature As Byte

对此

ByRef pbSignature As Byte

Answer 2

经过多次挫折和毫无结果的研究后，我终于发现了问题所在。一路上我发现问题完全出在代码的另一部分。我还发现问题也出现在 Windows 10 32 位上 - 所以不是 64 位问题。

先前调用 CryptImportKey 时错误填充的 dwflags 参数似乎并未阻止在 Vista 32 位下成功调用 CryptVerifySignature，即使在调查中调用 CryptImportKey 失败。一旦 CryptImportKey 的 dwflags 参数被更正为 CRYPT_EXPORTABLE 或 CRYPT_NO_SALT，它就成功了，随后对 CryptVerifySignature 的调用在我能够测试的所有替代操作系统/位号组合下都成功了。

向所有在此事中寻求帮助的人表示歉意和感谢。下次见。

VB 使用 advapi32.dll cryptverifysignature 的代码适用于 Vista SP2 而不是 Windows 10 64 位

VB code using advapi32.dll cryptverifysignature works on Vista SP2 not on Windows 10 64-bit

vb6

api

encryption

vba

cryptoapi