为什么这个 clojure 宏需要 `'~？

Question

（很抱歉，如果这是另一个问题的重复，我搜索所有那些花哨的特殊字符没有产生任何结果。）

我正在阅读 Mastering Clojure Macros 并且无法理解以下示例：

(defmacro inspect-caller-locals []
  (->> (keys &env)
       (map (fn [k] [`'~k k]))
       (into {})))
=> #'user/inspect-caller-locals
(let [foo "bar" baz "quux"]
  (inspect-caller-locals))
=> {foo "bar", baz "quux"}

下面的和更简单的'k有什么区别？

`'~k

据我所知，最里面的反引号 ~ 应该简单地恢复最外面的语法引号 ` 的效果，但是一个简短的实验表明它还有更多内容：

(defmacro inspect-caller-locals-simple []
  (->> (keys &env)
       (map (fn [k] ['k k]))
       (into {})))
=> #'user/inspect-caller-locals-simple
(let [foo "bar" baz "quux"]
  (inspect-caller-locals-simple))
CompilerException java.lang.RuntimeException: Unable to resolve symbol: k in this context, compiling:(/tmp/form-init4400591386630133028.clj:2:3)

不幸的是，我通常的调查方法在这里不适用：

(macroexpand '(let [foo "bar" baz "quux"]
                 (inspect-caller-locals)))
=> (let* [foo "bar" baz "quux"] (inspect-caller-locals))
(let [foo "bar" baz "quux"]
  (macroexpand '(inspect-caller-locals)))
=> {}

我在这里错过了什么？

Answer 1

我们先来确定宏里面的k是什么：

(defmacro inspect-caller-locals []
  (mapv (fn [k]
          (println (class k)))
        (keys &env))
  nil)
(let [x 1]
  (inspect-caller-locals))
;; Prints:
;; clojure.lang.Symbol

所以你每个k函数里面都是一个符号。如果您 return 来自宏的符号（即从它生成代码），clojure 将查找它引用的值并打印它。例如你可以这样做：

(defmacro inspect-caller-locals []
  (mapv (fn [k]
          [(quote x) k]) ;; not the "hard coded" x
        (keys &env)))
(let [x 1]
  (inspect-caller-locals))
;; Prints:
;; [[1 1]]

然而，您想要的是实际符号。问题（如您所述）是 quote 是一种特殊形式，无论您传递给它什么，它都不会评估。即k不会获取函数参数，而是保持k，通常不会定义：

(defmacro inspect-caller-locals []
  (mapv (fn [k]
          [(quote k) k])
        (keys &env)))
(let [x 1]
  (inspect-caller-locals))
;; => Error
(let [k 1]
  (inspect-caller-locals))
;; Prints:
;; [[1 1]]

您需要以某种方式评估您传递给 quote 的内容，但是这是不可能的，因为那不是 quote 所做的。其他函数，比如str没有这个问题：

(defmacro inspect-caller-locals []
  (mapv (fn [k]
          [(str k) k])
        (keys &env)))
(let [x 1]
  (inspect-caller-locals))
;; Prints:
;; [["x" 1]]

诀窍是更深入一层并引用 quote 本身，这样您就可以将符号传递给它：

(defmacro inspect-caller-locals []
  (mapv (fn [k]
          [;; This will evaluate k first but then generate code that 
           ;; wraps that symbol with a quote:
           (list (quote quote) k)
           ;; Or equivalently and maybe easier to understand:
           (list 'quote k)
           k])
        (keys &env)))
(let [x 1]
  (inspect-caller-locals))
;; Prints:
;; [[x x 1]]

或者使用可以为您执行此操作的 reader：

(defmacro inspect-caller-locals []
  (mapv (fn [k]
          [`(quote ~k)
           `'~k
           k])
        (keys &env)))
(let [x 1]
  (inspect-caller-locals))
;; Prints:
;; [[x x 1]]

因为毕竟：

(read-string "`'~k")
=> (clojure.core/seq (clojure.core/concat (clojure.core/list (quote quote)) (clojure.core/list k)))
(defmacro inspect-caller-locals []
  (mapv (fn [k]
          [(clojure.core/seq (clojure.core/concat (clojure.core/list (quote quote)) (clojure.core/list k)))
           k])
        (keys &env)))
(let [x 1]
  (inspect-caller-locals))
;; Prints:
;; [[x 1]]

Answer 2

一些替代和等效的写作方式

`'~k

是：

`(quote ~k) ;; expands the ' reader macro to the quote special form

(list 'quote k) ;; avoids syntax quote entirely

你的想法很对

the innermost unquote ~ should simply reverts the effect of the outermost syntax-quote

您的描述中唯一缺少的是您不能将 quote 拉到语法引用表达式之外，因为 quote 是一种特殊形式，会改变其中内容的含义.除此以外， '`~k 将等同于 'k - 正如您所注意到的，它不是！

我会附和@amalloy 的一般建议，即在 macros/macroexpansion 上下文外部的 REPL 中尝试语法引用的内容是最好的方法了解这些事情。

p.s。另外，我会记下我需要在未来的书籍版本中通过更好的解释来解决这个困惑 ;)

为什么这个 clojure 宏需要 `'~？

Why does this clojure macro need `'~?

macros

clojure

quote