xsl 中的自定义分组

Question

您好，我遇到了一个问题，需要一种相当专业的分组，并且希望获得有关最佳方法的反馈。这是一些 xml:

<root>
  <locations>
    <location>
      <address>123 4 st Smallville</address>
      <number>1</number>
    </location>
    <location>
      <address>432 1 st Metropolis</address>
      <number>2</number>
    </location>
  </locations>
  <insuranceCoverages>
    <coverage>
      <name>General Coverage</name>
      <locationSplits>
        <coverage>
          <name>Building Coverage</name>
          <locationNumber>1</locationNumber>
          <clauses>
            <coverage>
              <name>Earthquake Exclusion</name>
            </coverage>
          </clauses>
        </coverage>
      </locationSplits>
    </coverage>
    <coverage>
      <name>General Liability</name>
    </coverage>
  </insuranceCoverages>
</root>

我想做的是按位置将覆盖范围分组到一个相当平坦的层次结构中。类似于：

┌Location 1
├┬Coverage "Building Coverage"
│└Coverage "Earthquake Exclusion"
├Location 2
├No Location
├┬Coverage "General Coverage"
│└Coverage "General Liability"

我当前的解决方案使用 locations/location 上的模板并枚举覆盖范围列表以查找与当前位置匹配的位置编号。但是，由于该算法枚举了每个位置的所有覆盖范围，因此

O(nm)
  where n = # locations + 1
        m = # coverages

如果我的算法可以优化为仅遍历覆盖树一次，根据自身或其祖先的当前位置将每个覆盖放入一个集合中，然后打印出这些集合，我会更愿意。

O(n)
  where n = # coverages

当然，如果有更有效的方法用 xsl 表达这一点，（可能用 xsl:for-each-group 指令？）我也有兴趣听听。

Answer 1

我不确定这种方法是否足够有效 - 使用匹配每个 location 的模板与匹配 locationSplits 的 locationNumber 子元素的 number

<xsl:template match="location[number=//coverage//locationNumber]">

和第二个模板相互匹配 location，以下 XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" omit-xml-declaration="yes" encoding="UTF-8" indent="yes" />
  <xsl:strip-space elements="*" />
    <xsl:template match="insuranceCoverages">
      <xsl:apply-templates />
    </xsl:template>
    <xsl:template match="@*|node()">
      <xsl:apply-templates select="@*|node()" />
    </xsl:template>
    <xsl:template match="location[number=//coverage//locationNumber]">
      <xsl:variable name="number" select="number" />
      <xsl:text>Location</xsl:text>
      <xsl:value-of select="$number" />
      <xsl:text>Coverage:</xsl:text>
      <xsl:value-of select="//locationSplits//coverage[locationNumber=$number]/name" />
      <xsl:for-each select="//locationSplits//coverage[locationNumber=$number]/clauses/coverage">
        <xsl:text>Coverage:</xsl:text>
        <xsl:value-of select="name" />
    </xsl:for-each>
  </xsl:template>
  <xsl:template match="location">
    <xsl:variable name="number" select="number" />
    <xsl:text>Location</xsl:text>
    <xsl:value-of select="$number" />
    <xsl:text>No Location</xsl:text>
    <xsl:for-each select="//insuranceCoverages//coverage[not(ancestor::locationSplits)]">
      <xsl:text>Coverage:</xsl:text>
      <xsl:value-of select="name" />
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

当应用于您的输入时 XML 产生输出

Location 1
Coverage: Building Coverage
Coverage: Earthquake Exclusion
Location 2
No Location
Coverage: General Coverage
Coverage: General Liability

我不确定 locationSplits 中的覆盖范围的多个子句是否可能，所以也许没有必要循环它们。
在 locationSplits 中没有 coverage 的模板匹配 location 只打印 insurangeCoverages 的每个 coverage 子元素，它不是 locationSplits 的子元素：

<xsl:for-each select="//insuranceCoverages//coverage[not(ancestor::locationSplits)]">

Answer 2

if there are more efficient ways of expressing this with xsl,

使用 XSLT 执行此操作的有效方法是使用 key。这是一个简单的例子：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="coverage-by-location" match="coverage" use="locationNumber" />

<xsl:template match="/root">
    <xsl:copy>
        <xsl:for-each select="locations/location">
            <location number="{number}">
                <xsl:for-each select="key('coverage-by-location', number)">
                    <coverage name="{name}"/>
                </xsl:for-each>
            </location>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

这只遍历树的 locations/location 分支，并使用 <key> 指令创建的索引以 select 对应于当前位置的覆盖范围。

将 "No location" 的另一个分支添加到输出树中稍微有点棘手，但可以通过将键修改为：

来完成

<xsl:key name="coverage-by-location" match="coverage" use="string(locationNumber)" />

此时，用一个模板来处理两种覆盖会更方便，所以：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="coverage-by-location" match="coverage" use="string(locationNumber)" />

<xsl:template match="/root">
    <xsl:copy>
        <xsl:apply-templates select="locations/location"/>
        <no-location>
            <xsl:apply-templates select="key('coverage-by-location', '')"/>
        </no-location>
    </xsl:copy>
</xsl:template>

<xsl:template match="location">
    <location number="{number}">
        <xsl:apply-templates select="key('coverage-by-location', number)"/>
    </location>
</xsl:template>

<xsl:template match="coverage">
    <coverage name="{name}"/>
</xsl:template>

</xsl:stylesheet>

将此应用于您的输入示例将 return:

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <location number="1">
      <coverage name="Building Coverage"/>
   </location>
   <location number="2"/>
   <no-location>
      <coverage name="General Coverage"/>
      <coverage name="Earthquake Exclusion"/>
      <coverage name="General Liability"/>
   </no-location>
</root>

这与您预期的结果有点不同，但您没有解释 "Earthquake Exclusion" 覆盖范围与位置 #1 的关联程度。

编辑：

As for the Earthquake exclusion, it is important for it to end up under the location 1 element because it is a child of another coverage at location 1.

在这种情况下，我认为最好将密钥更改为：

<xsl:key name="coverage-by-location" match="coverage" use="string(ancestor-or-self::coverage/locationNumber)" />

xsl 中的自定义分组

Custom grouping in xsl

algorithm

xslt

grouping