Lazarus/Delphi：自分配记录数据类型中的 UnicodeString 导致访问冲突

Question

我想，我的问题是由 UnicodeStrings 的实现方式引起的，但我无法解决这个问题。

我正在尝试以递归方式扫描磁盘上的目录树并构建一个应该显示所有文件和子文件夹的树视图。另外，我想为每个树节点存储附加信息。 TTreeNode 对象只有一个 "Data" 属性（类型指针）用于此目的，因此我手动分配内存，存储信息并将分配的指针分配给我的数据属性。除非我在数据记录中使用 UnicodeString 字段，否则一切似乎都正常。

所以，这是我的自定义数据记录定义：

type
  TFileInformation = record
    AbsoluteFileName: UnicodeString;
    FileSize: Int64;
    FileAttributes: LongInt;
    CreationTime, ModificationTime: TDateTime;
  end;

这是我的目录回避代码：

const NO_ERROR = 0;

procedure ScanDirectory(Folder: UnicodeString; Node: TTreeNode);

var
  Details: Pointer;
  NewNode: TTreeNode;
  SearchAttributes: LongInt;
  SearchMask: UnicodeString;
  SearchRecord: TUnicodeSearchRec;

begin
  if (Folder <> '') and (Folder[Length(Folder)] <> DirectorySeparator) then begin
    Folder += DirectorySeparator;
  end;
  SearchMask := Folder + '*'{$IFDEF WINDOWS} + '.*'{$ENDIF};
  SearchAttributes := faReadOnly or faHidden or faSysFile or faDirectory or faArchive or faSymLink;

  if FindFirst(SearchMask, SearchAttributes, SearchRecord) = NO_ERROR then begin
    repeat
      if ((SearchRecord.Attr and faDirectory) <> faDirectory) or
         ((SearchRecord.Name <> '.') and (SearchRecord.Name <> '..')) then begin
        Details := MemAlloc(SizeOf(TFileInformation));
        //TFileInformation(Details^).AbsoluteFileName := Folder + SearchRecord.Name;
        TFileInformation(Details^).FileAttributes := SearchRecord.Attr;
        TFileInformation(Details^).FileSize := SearchRecord.Size;
        TFileInformation(Details^).CreationTime := SearchRecord.Time;
        //TFileInformation(Details^).ModificationTime := -1;
        if Node = nil then begin
          NewNode := self.trvOrigin.Items.AddNode(nil, nil, ansistring(SearchRecord.Name), Details, naAdd);
        end else begin
          NewNode := self.trvOrigin.Items.AddNode(nil, Node, ansistring(SearchRecord.Name), Details, naAddChild);
        end;

        if (SearchRecord.Attr and (faDirectory or faSymLink)) = faDirectory then begin
          // only recurse folders which are NOT SymLink:
          ScanDirectory(Folder + SearchRecord.Name, NewNode);
        end;
      end;
    until FindNext(SearchRecord) <> NO_ERROR;
  end;
  FindClose(SearchRecord);
end;

当我取消注释包含 .AbsoluteFileName := 的行时，我遇到了访问冲突（Unix 中的 SIGSEGV 异常）。我目前在 Debian Linux 上以 objfpc 模式使用 Lazarus，但我猜它与 Windows 上的 Delphi 相同。 Treeview.Data 属性值存储在我的示例代码中的 "Details" 变量中，self.trvOrigin 是我的树视图控件。

Answer 1

分配Details记录时，未定义内存。

AbsoluteFileName 是托管类型，使用前必须正确初始化。分配后需要清空内存：

FillChar(Details^, SizeOf(TFileInformation), #0);

作为替代方案，将 New(Details) 与 Dispose(Details) 结合使用。他们会正确地initialize/finalize记录。

注意：Details必须是类型指针，PFileInformation。

Lazarus/Delphi：自分配记录数据类型中的 UnicodeString 导致访问冲突

Lazarus/Delphi: UnicodeString in self-allocated record data type causes access violations

delphi

unicode-string

lazarus

dynamic-memory-allocation