如何使用 XSLT 根据兄弟姐妹对元素进行分组

Question

我正在尝试根据周围兄弟姐妹的开始和结束属性对几个元素进行分组。

样本XML：

<list>
  <item>One</item>
  <item class="start">Two</item>
  <item>Three</item>
  <item class="end">Four</item>
  <item>Five</item>
  <item class="start">Six</item>
  <item class="end">Seven</item>
  <item>Eight</item>
</list>

期望的结果：

<body>
  <p>One</p>
  <div>
    <p>Two</p>
    <p>Three</p>
    <p>Four</p>
  </div>
  <p>Five</p>
  <div>
    <p>Six</p>
    <p>Seven</p>
  </div>
  <p>Eight</p>
</body>

我使用以下 XSLT 接近预期的结果。但是，后续兄弟匹配在到达结束属性后不会停止。此外，标准匹配会重复已从以下兄弟匹配中输出的元素。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
    <xsl:strip-space elements="*" />
    <xsl:template match="/">
        <xsl:apply-templates />
    </xsl:template>
    <xsl:template match="list">
        <body>
            <xsl:apply-templates />
        </body>
    </xsl:template>
    <xsl:template match="item">
        <p>
            <xsl:apply-templates />
        </p>
    </xsl:template>
    <xsl:template match="item[@class='start']">
        <div>
            <p><xsl:apply-templates /></p>
            <xsl:apply-templates select="following-sibling::*[not(preceding-sibling::*[1][@class='end'])]" />
        </div>
    </xsl:template>
</xsl:transform>

Answer 1

既然您正在使用 XSLT 2.0，为什么不利用它：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/list">
    <body>
        <xsl:for-each-group select="item" group-starting-with="item[@class='start']">
            <xsl:for-each-group select="current-group()" group-ending-with="item[@class='end']">
                <xsl:choose>
                    <xsl:when test="count(current-group()) gt 1">
                        <div>
                            <xsl:apply-templates select="current-group()" />
                        </div>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="current-group()" />
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:for-each-group>
    </body>
</xsl:template>

<xsl:template match="item">
    <p>
        <xsl:value-of select="."/>
    </p>
</xsl:template>

</xsl:stylesheet>

如何使用 XSLT 根据兄弟姐妹对元素进行分组

How to group elements based on their siblings using XSLT

xslt

xslt-2.0