从 tkSet 中知道选择的 tkEnumeration

Question

我需要做一个函数来了解对象的所有已发布属性及其值。除了 tkSet 属性之外，我已经完成了一个执行此操作的函数。我可以从 tkSet 中获取 tkEnumeration 元素，但我不知道如何知道是否选择了 tkEnumeration。

这是我的函数

  procedure TForm1.GetObjectProperties(Obj: TObject; List: TStrings;
    Level: Integer);

    function GetSubPropObject(Obj: TObject; APropName: string): TObject;
    var
      PropInfo: PPropInfo;
    begin
      Result := nil;
      try
        PropInfo := GetPropInfo(Obj, APropName);
        if Assigned(PropInfo) and (PropInfo.PropType^.Kind in [tkClass]) then
        begin
          Result := GetObjectProp(Obj, PropInfo);
        end;
      except
        on E: Exception do
          List.Add(Obj.ClassName + ' ----- ' + E.Message);
      end;
    end;

    // ==> with this procedure I obtains the tkEnumeration elements from a tkSet
    procedure GetSetInformation(AOrdTypeInfo: PTypeInfo; Space: string);
    var
      OrdTypeData: PTypeData;
      TypeNameStr: string;
      TypeKindStr: string;
      MinVal, MaxVal: Integer;
      i: integer;
    begin
      Space := Space + '     ';
       // Get the TTypeData pointer
      OrdTypeData := GetTypeData(AOrdTypeInfo);
       // Get the type name string
      //TypeNameStr := string(AOrdTypeInfo.Name);
       // Get the type kind string
      //TypeKindStr := GetEnumName(TypeInfo(TTypeKind), Integer(AOrdTypeInfo^.Kind));

      MinVal := OrdTypeData^.MinValue;
      MaxVal := OrdTypeData^.MaxValue;

      if AOrdTypeInfo^.Kind = tkSet then
        GetSetInformation(OrdTypeData^.CompType^, Space);

      if AOrdTypeInfo^.Kind = tkEnumeration then
        for i := MinVal to MaxVal do
          List.Add(Space + GetEnumName(AOrdTypeInfo, i));
    end;
  var
    ctx: TRttiContext;
    rt: TRttiType;
    prop: TRttiProperty;
    Tmp: string;
    i: Integer;
  begin
    if not Assigned(Obj) or not Assigned(List) then Exit;

    Tmp := '';
    for i := 0 to (Level * 10) do
      Tmp := Tmp + ' ';

    ctx := TRttiContext.Create;
    try
      rt := ctx.GetType(Obj.ClassType);

      for prop in rt.GetProperties do
      begin
        if not prop.IsWritable then
          Continue;
        if TRttiInstanceType(prop.PropertyType).TypeKind in [tkMethod, tkPointer] then
          Continue;
        if prop.Visibility <> mvPublished then
          Continue;

        try
          //List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ' + prop.GetValue(Obj).ToString);
          case TRttiInstanceType(prop.PropertyType).TypeKind of
            tkInteger, tkInt64:
              List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ' + IntToStr(prop.GetValue(Obj).AsInteger));
            tkFloat:
              List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ' + FloatToStr(prop.GetValue(Obj).AsExtended));
            tkChar, tkString, tkWChar, tkLString, tkWString, tkUString:
              List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ' + prop.GetValue(Obj).AsString);
            tkEnumeration:
              List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ' + GetEnumName(prop.GetValue(Obj).TypeInfo, Ord(prop.GetValue(Obj).Kind)));
            tkSet:
              begin
                List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ');
                GetSetInformation(prop.GetValue(Obj).TypeInfo, Tmp);
              end;
            else
              List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + ') ' + ' --- ' + GetEnumName(TypeInfo(TTypeKind), Ord(TRttiInstanceType(prop.PropertyType).TypeKind)));
          end;
        except
          List.Add(Tmp + prop.Name + ' ERROR TypeCast');
        end;

        if TRttiInstanceType(prop.PropertyType).TypeKind = tkClass then
          GetObjectProperties(GetSubPropObject(Obj, prop.Name), List, Level + 1);
      end;
    finally
      ctx.Free;
    end;
  end;

有什么解决办法吗？谢谢！

Answer 1

它不太符合当前写入的输出格式，但您可以通过简单地使用 ToString 值本身的方法。

因此，您目前拥有的位置：

       tkSet:
          begin
            List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ');
            GetSetInformation(prop.GetValue(Obj).TypeInfo, Tmp);
          end;

例如，在表单上的默认 Anchors 的情况下，将输出：

Anchors:
    akLeft
    akTop
    akRight
    akBottom

你可以这样写：

       tkSet:
          begin
            List.Add(Tmp + prop.Name + ' (' + string(prop.GetValue(Obj).TypeInfo.Name) + '): ' + prop.GetValue(Obj).ToString);
          end;

对于表单上 Anchors 属性的相同默认值，现在将输出：

Anchors: [akLeft,akTop]

如果您需要转换为实际的枚举值或以其他格式呈现它们，从该字符串中提取各个成员名称并使用它们获取值或以其他格式呈现数据应该是一个相对简单的练习任何你需要的格式。

从 tkSet 中知道选择的 tkEnumeration

Know selected tkEnumeration from a tkSet

delphi

rtti