FSM 在 verilog 中实现去抖动电路（时间刻度错误）

Question

我需要解决 FPGA Prototyping By Verilog Examples 中的一个问题Pong

如果是作者错误或者我做错了什么当我在 vivado 上模拟时，我没有发现

有任何变化

    q_reg <= q_next;    //   ? q_next never initialised ???
   // next-state logic    //  How he wants to set time tick ?
   assign q_next = q_reg + 1;
   // output tick

去抖动电路的状态图。定义为图片

考虑部分
// 计数器生成 10 ms tick

module db_fsm
   (
    input wire clk, reset,
    input wire sw,
    output reg db
   );

   // symbolic state declaration
   localparam  [2:0]
               zero    = 3'b000,
               wait1_1 = 3'b001,
               wait1_2 = 3'b010,
               wait1_3 = 3'b011,
               one     = 3'b100,
               wait0_1 = 3'b101,
               wait0_2 = 3'b110,
               wait0_3 = 3'b111;

   // number of counter bits (2^N * 20ns = 10ms tick)
   localparam N =19;

   // signal declaration
   reg [N-1:0] q_reg;
   wire [N-1:0] q_next;
   wire m_tick;
   reg [2:0] state_reg, state_next;

   // body

   //=============================================
   // counter to generate 10 ms tick
   //=============================================
   always @(posedge clk)
      q_reg <= q_next;
   // next-state logic
   assign q_next = q_reg + 1;
   // output tick
   assign m_tick = (q_reg==0) ? 1'b1 : 1'b0;

   //=============================================
   // debouncing FSM
   //=============================================
   // state register
    always @(posedge clk, posedge reset)
       if (reset)
          state_reg <= zero;
       else
          state_reg <= state_next;

   // next-state logic and output logic
   always @*
   begin
      state_next = state_reg;  // default state: the same
      db = 1'b0;               // default output: 0
      case (state_reg)
         zero:
            if (sw)
               state_next = wait1_1;
         wait1_1:
            if (~sw)
               state_next = zero;
            else
               if (m_tick)
                  state_next = wait1_2;
         wait1_2:
            if (~sw)
               state_next = zero;
            else
               if (m_tick)
                  state_next = wait1_3;
         wait1_3:
            if (~sw)
               state_next = zero;
            else
               if (m_tick)
                  state_next = one;
         one:
            begin
              db = 1'b1;
              if (~sw)
                 state_next = wait0_1;
            end
         wait0_1:
            begin
               db = 1'b1;
               if (sw)
                  state_next = one;
               else
                 if (m_tick)
                    state_next = wait0_2;
            end
         wait0_2:
            begin
               db = 1'b1;
               if (sw)
                  state_next = one;
               else
                 if (m_tick)
                    state_next = wait0_3;
            end
         wait0_3:
            begin
               db = 1'b1;
               if (sw)
                  state_next = one;
               else
                 if (m_tick)
                    state_next = zero;
            end
         default: state_next = zero;
      endcase
   end

endmodule

Answer 1

q_next不需要初始化，是从q_reg导出的组合逻辑。 q_reg 未明确初始化，因此将采用默认值。

FPGA 上触发器的默认值为 0，但对于模拟器，默认值为 X。出现这种差异的原因是因为 Verilog 也用于模拟集成电路 (IC)；由于技术节点、制造过程和变化、温度等原因，who flops 可以具有看似随机的初始值。

由于您的目标是 FGPA，简单的解决方案是添加行 initial q_reg = {N{1'b0}}; 或将 reg [N-1:0] q_reg; 更改为 reg [N-1:0] q_reg = {N{1'b0}}; 无论哪种初始化方式 q_reg 都会让您使用 Verilog仿真和FPGA匹配。

顺便说一句：对于作为目标的 ASIC，FPGA 解决方案将不起作用（初始化器被 ASIC 合成器忽略）。 ASIC 解决方案是向分配触发器的始终块添加重置条件（同步或异步）。 ASIC 解决方案确实适用于 FPGA，但是 FPGA 通常具有有限数量（如果有的话）的异步触发器 reset/set

FSM 在 verilog 中实现去抖动电路（时间刻度错误）

FSM implementation of a debouncing circuit in verilog ( error in time tick)

verilog

fpga

fsm