SPARQL DISTINCT 在 Virtuoso 中给出重复项

Question

即使使用了 DISTINCT 子句，以下 SPARQL 查询也会在 Virtuoso 中给出重复项。您可以在 DBpedia public endpoint 中测试查询。查询有什么问题？

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX dbpedia:<http://dbpedia.org/resource/>
PREFIX dbpedia-owl:<http://dbpedia.org/ontology/>
PREFIX dbpprop: <http://dbpedia.org/property/>
PREFIX vrank:<http://purl.org/voc/vrank#>
SELECT DISTINCT ?person1 ?person1_id ?person2 ?person2_id ?person2_rank
FROM <http://dbpedia.org> 
FROM <http://people.aifb.kit.edu/ath/#DBpedia_PageRank> 
WHERE {
    ?person1 rdf:type dbpedia-owl:Person.
    ?person2 rdf:type dbpedia-owl:Person.
    ?person1 ?link ?person2.
    ?person1 dbpedia-owl:wikiPageID ?person1_id.
    ?person2 dbpedia-owl:wikiPageID ?person2_id.
    ?person2 vrank:hasRank/vrank:rankValue ?person2_rank.
    FILTER (?person1_id != ?person2_id).
    FILTER (?person1_id = 308)
} ORDER BY DESC(?person2_rank) ASC(?person2_id)

SPARQL results

结果包括看似重复的行，例如：

http://dbpedia.org/resource/Aristotle 308 http://dbpedia.org/resource/Democritus  8211 27.281
http://dbpedia.org/resource/Aristotle 308 http://dbpedia.org/resource/Democritus  8211 27.281
http://dbpedia.org/resource/Aristotle 308 http://dbpedia.org/resource/Heraclitus 13792 26.6914
http://dbpedia.org/resource/Aristotle 308 http://dbpedia.org/resource/Heraclitus 13792 26.6914
http://dbpedia.org/resource/Aristotle 308 http://dbpedia.org/resource/Parmenides 23575 19.6082
http://dbpedia.org/resource/Aristotle 308 http://dbpedia.org/resource/Parmenides 23575 19.6082

Answer 1

我可以确认结果中似乎有重复项。我不确定重复的问题是什么，但我想知道它是否与浮点数的不精确相等有关。如果不是直接 select 浮点数，而是 select 它们的词法形式（注意 (str(... ) 作为 ?rank) 最后:

SELECT DISTINCT
  ?person1 ?person1_id
  ?person2 ?person2_id
  (str(?person2_rank) as ?rank)

我得到 none 个重复项。这可能值得作为错误报告给 Virtuoso 人员。对于它的价值，如果你想要排名的浮点值，你可以使用 xsd:float 作为函数将该字符串转换回浮点值，当我这样做，select 如下所示，我仍然得到预期的 distinct 结果。

SELECT DISTINCT
  ?person1 ?person1_id
  ?person2 ?person2_id
  (xsd:float(str(?person2_rank)) as ?rank)

SPARQL results

Answer 2

虽然这对您的 dbpedia 查询没有帮助，但任何通过搜索对模型和数据有控制权的标题到达这里的人可能想知道：

virtuoso double 似乎没有遇到这个 SELECT DISTINCT 问题 float

SPARQL DISTINCT 在 Virtuoso 中给出重复项

SPARQL DISTINCT gives duplicates in Virtuoso

sparql

dbpedia

virtuoso