在 Haskell 中简单地键入 lambda 演算失败

Question

我是 Haskell 的新手，如果这个问题没有太大意义，我深表歉意。

我希望能够在 Haskell 中实现简单类型的 lambda 表达式，这样当我尝试将表达式应用于另一个 错误的 类型时，结果不是类型错误，而是一些设定值，例如没有什么。起初我认为使用 Maybe monad 是正确的方法，但我无法使任何工作正常进行。我想知道这样做的正确方法是什么（如果有的话）。

问题的上下文（如果有帮助的话）是我正在从事的一个项目，该项目将 POS（词性）标签分配给句子中的单词。对于我的标签集，我使用的是分类语法类型；这些是类型化的 lambda 表达式，如 (e -> s) 或 (e -> (e -> s))，其中 e 和 s 分别是名词和句子的类型。因此，例如，kill 的类型为 (e -> (e -> s)) - 它包含两个名词短语和 returns 一个句子。我想要一个函数，它接受此类对象的列表，并找出是否有任何方法可以将它们组合起来以达到 s 类型的对象。当然，这正是 Haskell 的类型检查器所做的，所以为每个单词分配一个适当类型的 lambda 表达式应该很简单，让 Haskell 完成其余的工作。问题是，如果无法达到 s，Haskell 的类型检查器自然会停止程序运行。

Answer 1

非常标准的东西。只需编写一个类型检查器，并且仅在进行类型检查时评估术语。 evalMay 这样做。您当然可以丰富常量和基本类型的集合；为了简单起见，我只使用了每一种。

import Control.Applicative ((<$), (<$>))
import Control.Monad (guard)
import Safe (atMay)

data Type
    = Base
    | Arrow Type Type
    deriving (Eq, Ord, Read, Show)

data Term
    = Const
    | Var Int -- deBruijn indexing; the nearest enclosing lambda binds Var 0
    | Lam Type Term
    | App Term Term
    deriving (Eq, Ord, Read, Show)

check :: [Type] -> Term -> Maybe Type
check env Const = return Base
check env (Var v) = atMay env v
check env (Lam ty tm) = Arrow ty <$> check (ty:env) tm
check env (App tm tm') = do
    Arrow i o <- check env tm
    i' <- check env tm'
    guard (i == i')
    return o

eval :: Term -> Term
eval (App tm tm') = case eval tm of
    Lam _ body -> eval (subst 0 tm' body)
eval v = v

subst :: Int -> Term -> Term -> Term
subst n tm Const = Const
subst n tm (Var m) = case compare m n of
    LT -> Var m
    EQ -> tm
    GT -> Var (m-1)
subst n tm (Lam ty body) = Lam ty (subst (n+1) tm body)
subst n tm (App tm' tm'') = App (subst n tm tm') (subst n tm tm'')

evalMay :: Term -> Maybe Term
evalMay tm = eval tm <$ check [] tm

Answer 2

我想用一种稍微不同的方法扩展@Daniel Wagner 的出色答案：不是类型检查 return 一个有效类型（如果有的话），return 一个类型化的表达式然后保证我们可以对其进行评估（因为简单类型的 lambda 演算是强归一化的）。基本思想是 check ctx t e returns Just (ctx |- e :: t) 当且仅当 e 可以在某些上下文 ctx 中输入 t，然后给出一些输入表达式 ctx |- e :: t，我们可以在一些 Env 正确类型的铁器中计算它。

实施

我将使用单例来模拟 check :: (ctx :: [Type]) -> (a :: Type) -> Term -> Maybe (TTerm ctx a) 的 Pi 类型，这意味着我们需要打开每个 GHC 扩展和厨房水槽：

{-# LANGUAGE GADTs #-}
{-# LANGUAGE DataKinds, KindSignatures, TypeFamilies, TypeOperators #-}
{-# LANGUAGE TemplateHaskell #-} -- sigh...

import Data.Singletons.Prelude
import Data.Singletons.TH
import Data.Type.Equality

第一位是无类型表示，直接来自@Daniel Wagner 的回答：

data Type = Base
          | Arrow Type Type
          deriving (Show, Eq)

data Term = Const
          | Var Int
          | Lam Type Term
          | App Term Term
          deriving Show

但我们还将通过将 Base 解释为 () 和将 Arrow t1 t2 解释为 t1 -> t2:

来为这些类型提供语义

 type family Interp (t :: Type) where
    Interp Base = ()
    Interp (Arrow t1 t2) = Interp t1 -> Interp t2

为了与 de Bruijn 主题保持一致，上下文是类型列表，变量是上下文的索引。给定上下文类型的环境，我们可以查找变量索引以获取值。注意lookupVar是一个总函数。

data VarIdx (ts :: [Type]) (a :: Type) where
    Here :: VarIdx (a ': ts) a
    There :: VarIdx ts a -> VarIdx (b ': ts) a

data Env (ts :: [Type]) where
    Nil :: Env '[]
    Cons :: Interp a -> Env ts -> Env (a ': ts)

lookupVar :: VarIdx ts a -> Env ts -> Interp a
lookupVar Here      (Cons x _)  = x
lookupVar (There v) (Cons _ xs) = lookupVar v xs

好的，我们已经准备好所有的基础设施来实际编写一些代码。首先，让我们定义 Term 的类型化表示，以及一个（总计！）求值器：

data TTerm (ctx :: [Type]) (a :: Type) where
    TConst :: TTerm ctx Base
    TVar :: VarIdx ctx a -> TTerm ctx a
    TLam :: TTerm (a ': ctx) b -> TTerm ctx (Arrow a b)
    TApp :: TTerm ctx (Arrow a b) -> TTerm ctx a -> TTerm ctx b

eval :: Env ctx -> TTerm ctx a -> Interp a
eval env TConst = ()
eval env (TVar v) = lookupVar v env
eval env (TLam lam) = \x -> eval (Cons x env) lam
eval env (TApp f e) = eval env f $ eval env e

到目前为止一切顺利。 eval 很好而且很全面，因为它的输入只能表示简单类型 lambda 演算的类型正确的项。因此，@Daniel 的评估者的部分工作必须在将无类型表示转换为有类型表示的过程中完成。

infer背后的基本思想是，如果类型推断成功，它returns Just $ TheTerm t e，其中t是Singleton witness of e的类型。

$(genSingletons [''Type])
$(singDecideInstance ''Type)

-- I wish I had sigma types...
data SomeTerm (ctx :: [Type]) where
    TheTerm :: Sing a -> TTerm ctx a -> SomeTerm ctx

data SomeVar (ctx :: [Type]) where
    TheVar :: Sing a -> VarIdx ctx a -> SomeVar ctx

-- ... and pi ones as well
infer :: Sing ctx -> Term -> Maybe (SomeTerm ctx)
infer _ Const = return $ TheTerm SBase TConst
infer ts (Var n) = do
    TheVar t v <- inferVar ts n
    return $ TheTerm t $ TVar v
infer ts (App f e) = do
    TheTerm t0 e' <- infer ts e
    TheTerm (SArrow t0' t) f' <- infer ts f
    Refl <- testEquality t0' t0
    return $ TheTerm t $ TApp f' e'
infer ts (Lam ty e) = case toSing ty of
    SomeSing t0 -> do
        TheTerm t e' <- infer (SCons t0 ts) e
        return $ TheTerm (SArrow t0 t) $ TLam e'

inferVar :: Sing ctx -> Int -> Maybe (SomeVar ctx)
inferVar (SCons t _) 0 = return $ TheVar t Here
inferVar (SCons _ ts) n = do
    TheVar t v <- inferVar ts (n-1)
    return $ TheVar t $ There v
inferVar _ _ = Nothing

希望最后一步是显而易见的：因为我们只能在给定类型下评估类型良好的术语（因为这是给我们它的 Haskell 嵌入类型的东西），我们将类型 infer进入类型 checking:

check :: Sing ctx -> Sing a -> Term -> Maybe (TTerm ctx a)
check ctx t e = do
    TheTerm t' e' <- infer ctx e
    Refl <- testEquality t t'
    return e'

示例会话

让我们在 GHCi 中尝试我们的函数：

λ» :set -XStandaloneDeriving -XGADTs
λ» deriving instance Show (VarIdx ctx a)
λ» deriving instance Show (TTerm ctx a)

λ» let id = Lam Base (Var 0) -- \x -> x
λ» check SNil (SBase `SArrow` SBase) id
Just (TLam (TVar Here))

λ» let const = Lam Base $ Lam Base $ Var 1 -- \x y -> x
λ» check SNil (SBase `SArrow` SBase) const
Nothing -- Oops, wrong type
λ» check SNil (SBase `SArrow` (SBase `SArrow` SBase)) const
Just (TLam (TLam (TVar Here)))

λ» :t eval Nil <$> check SNil (SBase `SArrow` (SBase `SArrow` SBase)) const
eval Nil <$> check SNil (SBase `SArrow` (SBase `SArrow` SBase)) const
  :: Maybe (() -> () -> ())
-- Note that the `Maybe` there comes from `check`, not `eval`!
λ» let Just const' = check SNil (SBase `SArrow` (SBase `SArrow` SBase)) const
λ» :t eval Nil const'
eval Nil const' :: () -> () -> ()
λ» eval Nil const' () ()
()

在 Haskell 中简单地键入 lambda 演算失败

Simply typed lambda calculus with failure, in Haskell

lambda

haskell

typed

maybe

实施

示例会话