在 Cython 中包装自定义类型 C++ 指针

Question

使用 Cython 包装自定义类型 C++ 指针的最佳方法是什么？

例如：

import numpy as np
cimport numpy as np

cdef extern from "A_c.h"
    cdef cppclass A:
       A();
       void Foo(A* vec);

cdef class pyA:
    cdef A *thisptr
    def ___cinit___(self):
        self.thisptr = new A()
    def __dealloc___(self):
        del self.thisptr

我应该如何使用cython来包装Foo？我已经尝试了以下但我从 Buffer.py 或 A 不是 memoryview slice

的基本类型的错误中得到了断言错误

def Foo(self, np.ndarray[A, mode='c'] vec)
def Foo(self, A[::1] vec)

Answer 1

基本上每次你想传递一个类型为 A 的对象或指向它的指针时，你应该使用类型为 pyA 的对象 Python - 这实际上非常类似于一个指针，除了它有引用计数，所以它就像 C++11 中的 shared_ptr，只是它只知道 Python（或 Cython）中的引用。 [编辑] 请注意，Python 对象可以是 None，您可以使用 not None 子句轻松防止这种情况。

当然这不仅适用于参数而且适用于 return 类型，因此 return 指向类型 A 对象的每个方法都应该 return 取而代之的是 pyA-对象。为此，您可以创建一个 cdef 方法名称，例如 setThis 允许设置包含的指针。

如上所述，内存管理是在 Python 中完成的，如果您以这种方式包装指针，那么一方面您需要确保如果您的 C++ 对象持有指向对象的指针，那么 Python 对象不会被删除（例如，通过在 Cython 中存储对 Python 对象的引用），另一方面，如果对象仍包含在 Python 对象中，则不应从 C++ 中删除对象。如果您已经在 C++ 中进行了某种内存管理，则您还可以向 Cython 对象添加标志是否应删除 C++ 对象。

我对您的示例进行了一些扩展，以说明如何在 Cython 中实现它：

cdef extern from "A_c.h":
    cdef cppclass A:
        A()
        void Foo(A* vec)
        A* Bar()

    cdef cppclass AContainer:
        AContainer(A* element)

cdef class pyA:
    cdef A *thisptr
    def ___cinit___(self):
        self.thisptr = new A()

    def __dealloc___(self):
        del self.thisptr

    cdef setThis(self, A* other):
        del self.thisptr
        self.thisptr = other
        return self

    def Foo(self, pyA vec not None): # Prevent passing None
        self.thisptr.Foo(vec.thisptr)

    def Bar(self):
        return pyA().setThis(self.thisptr.Bar())

cdef class pyAContainer:
    cdef AContainer *thisptr
    cdef pyA element

    def __cinit__(self, pyA element not None):
        self.element = element # store reference in order to prevent deletion
        self.thisptr = new AContainer(element.thisptr)

    def __dealloc__(self):
        del self.thisptr # this should not delete the element
        # reference counting for the element is done automatically

在 Cython 中包装自定义类型 C++ 指针

Wrapping custom type C++ pointer in Cython

python

c++

pointers

numpy

cython