VB.Net 隐藏程序热键

Question

有没有办法注册热键以从不可见（隐藏）程序切换表单？我已经厌倦了常规方法，它们仅在表单可见或活动时有效 window。预先感谢您的帮助！

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Me.KeyPreview = True
    Me.ShowInTaskbar = False
    Me.ShowIcon = False
    Me.Visible = False
End Sub

这是隐藏程序的代码。

Answer 1

您想使用全局热键。请确保在程序关闭时取消注册。

摘自过去对我有帮助的 MSDN 文章：

Firstly, you need to know the Virtual-Key Codes.

http://msdn2.microsoft.com/en-us/library/ms927178.aspx You can then P/Invoke RegisterHotKey/UnregisterHotKey APIs to register/Unregister the hotkey. Code sample: Register multiple hotkeys such as Alt+D, Alt+C, etc.

Imports System.Runtime.InteropServices

Public Class Form1

    Public Const MOD_ALT As Integer = &H1 'Alt key
    Public Const WM_HOTKEY As Integer = &H312

    <DllImport("User32.dll")> _
    Public Shared Function RegisterHotKey(ByVal hwnd As IntPtr, _
                        ByVal id As Integer, ByVal fsModifiers As Integer, _
                        ByVal vk As Integer) As Integer
    End Function

    <DllImport("User32.dll")> _
    Public Shared Function UnregisterHotKey(ByVal hwnd As IntPtr, _
                        ByVal id As Integer) As Integer
    End Function

    Private Sub Form1_Load(ByVal sender As System.Object, _
                        ByVal e As System.EventArgs) Handles MyBase.Load
        RegisterHotKey(Me.Handle, 100, MOD_ALT, Keys.D)
        RegisterHotKey(Me.Handle, 200, MOD_ALT, Keys.C)
    End Sub

    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        If m.Msg = WM_HOTKEY Then
            Dim id As IntPtr = m.WParam
            Select Case (id.ToString)
                Case "100"
                    MessageBox.Show("You pressed ALT+D key combination")
                Case "200"
                    MessageBox.Show("You pressed ALT+C key combination")
            End Select
        End If
        MyBase.WndProc(m)
    End Sub

    Private Sub Form1_FormClosing(ByVal sender As System.Object, _
                        ByVal e As System.Windows.Forms.FormClosingEventArgs) _
                        Handles MyBase.FormClosing
        UnregisterHotKey(Me.Handle, 100)
        UnregisterHotKey(Me.Handle, 200)
    End Sub

End Class

VB.Net 隐藏程序热键

VB.Net Hidden Program Hotkeys

vb.net

hotkeys

keypress