在 xsl:if 中测试命名空间限定属性名称的正确方法是什么？

Question

我正在使用 xslt 2.0 测试 xsl:if 中的命名空间限定属性的名称。我有一个有效的解决方案，但我认为它是一个薄弱的解决方案，对特定的名称空间前缀很敏感。有关工作示例问题，请参阅 http://xsltransform.net/jyH9rMs/1。

示例输入：

<?xml version="1.0" encoding="utf-8"?>
<content xmlns:ex="http://example.com">
    <ex:t1>some content</ex:t1>
    <ex:t2>some content</ex:t2>
    <t3 ex:attr1="attr-val-1" ex:attr2="attr-val-2">more content</t3>
</content>

期望的输出：

<?xml version="1.0" encoding="UTF-8"?>
<content xmlns:ex="http://example.com">
    <ex:t1>some content</ex:t1>

    <t3 ex:attr1="attr-val-1">more content</t3>
</content>

在我的样式表中，我使用类似的逻辑来遍历元素和属性。对于元素，我可以使用 self::ex:t1 进行测试，但对于属性我必须求助于 name()='ex:attr1'。如果样式表中的名称空间前缀从 ex 更改为 ex1，则此属性逻辑将失败。 self:: 似乎不适用于属性节点，或者至少我无法让它工作。

In a xsl:if what is the correct way to test for a namespace-qualified attribute name?

我的样式表：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
               xmlns:ex="http://example.com" version="2.0">
    <xsl:output method="xml" encoding="UTF-8" indent="yes" />

    <xsl:template match="/">
        <xsl:apply-templates/>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="ex:*">
        <xsl:for-each select=".">
            <xsl:if test="self::ex:t1">
                <xsl:copy-of select="."/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="*[@ex:*]">
        <xsl:copy>
            <xsl:for-each select="@*">
                <xsl:if test="name()='ex:attr1'">
                <!--<xsl:if test="self::ex:attr1">-->
                    <xsl:attribute name="{name()}" select="."/>
                </xsl:if>
            </xsl:for-each>
            <xsl:apply-templates select="node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:transform>

编辑： 在我的生产系统中，上述问题是从中抽象出来的，我最终使用了 Michael Kay/Martin Honnen 建议的方法之一：<xsl:if test=". instance of attribute(ex:attr1)">。干净利落，直抒胸臆

其他解决方案运行正常，但我不喜欢 <xsl:if test=". is ../@ex:attr1"> 和 <xsl:if test="node-name(.)= resolve-QName('ex:attr1', ..)"> 中对 .. 的弱隐含依赖。 <xsl:if test="node-name(.) = QName('http://example.com', 'attr1')"> 不得不输入命名空间 URL.

Answer 1

例子不能代替解释。以下样式表完全按照您的要求生成结果 - 有意或巧合：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ex="http://example.com">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!-- remove ex:t2 -->
<xsl:template match="ex:t2"/>

<!-- remove ex:attr2 -->
<xsl:template match="@ex:attr2"/>

</xsl:stylesheet>

请注意，这里没有要测试的内容。

是的，您对 self:: 轴的看法是正确的：它永远不会指向属性（或命名空间）。不，这与命名空间中的属性无关。

Answer 2

选项包括

test=". instance of attribute(ex:attr1)"

或

test="node-name(.) = QName('namespace', 'attr1')"

或

test=". is ../@ex:attr1"

在 xsl:if 中测试命名空间限定属性名称的正确方法是什么？

What is the proper way to test a namespace-qualitified attribute name in a xsl:if?

xml

xslt

xslt-2.0

saxon