使用 VBA-Excel 进行跨多个数据库的 SQL 查询

Question

使用 Excel 2010，SQL 和 DAO

我正在尝试对驻留在当前电子表格之外的表执行查询。这将是微不足道的，在 Access 中，链接 tables/databases，但在 excel 中使用 VBA，我受阻了。

假设这些：

ExcelFileOne; Tab; various headed field/columns
ExcelFileTwo; Tab; various headed field/columns

我想在第三个 excel 文件中执行查询，它是这样的 [使用点符号进行解释，而不是编码....] -- 一个简单的例子：

SELECT FileOne.[Tab$].Fields, FileTwo.[Tab$].Fields, etc.
    FROM FileOne, FileTwo, Thisworkbook
    WHERE (FileOne.[Tab$].field2 <> FileTwo.[Tab$].Field2) 
        AND (ThisWorkbook.[Tab$].Field1 ....)

基本上，我想为该链接文件复制 Access 本机执行的操作。

指向正确方向的指针？

[[ 我可以使用一个指针来说明为什么在连接中使用 "Excel 8.0..." 在 Excel2010 上有效或失败，使用宏文件，以及如何在 network/system 对用户关闭.... ]]

Answer 1

您确实可以直接在 SQL 语句中使用 DAO 和 ADO 查询其他工作簿，同样可以通过简单地引用它们的路径来查询 Access 数据库表。相反，在 Access 查询中，您可以查询 Excel 个工作簿！这证明 Jet/ACE SQL 引擎（Windows .dll 文件）并不局限于任何一种 MS Office 产品或 Windows 程序，而是一种适用于所有人的工具。

在下面的两个示例中，宏直接连接到第一个工作簿，而在 SQL 查询中，每个宏都间接连接到第二个工作簿。您可以运行在任一工作簿内部或外部编写代码。运行s genric INNER JOIN on FileOne and FileTwo worksheets but any compliant Jet/ACE SQL 声明应该有效。并且两个输出查询结果都在预先存在的 RESULTS 选项卡中。

DAO

Dim dbE As Object, db As Object, rst As Object
Dim sqlString As String
Dim i As Integer
Const dbOpenDynaset = 2, dbReadOnly = 4

' OPEN DB CONNECTION
Set dbE = CreateObject("DAO.DBEngine.120")  'ALSO TRY: DAO.DBEngine.35 OR .36   
Set db = dbE.OpenDatabase("C:\Path\To\FileOne.xlsm", False, True, "Excel 12.0 Xml;HDR=Yes")

' OPEN QUERY RECORDSET
sqlString = " SELECT * FROM [TAB$] t1" _
              & " INNER JOIN (SELECT * FROM" _
              & " [Excel 12.0 Xml;HDR=Yes;Database=C:\Path\To\FileTwo.xlsm].[TAB$]) t2" _
              & " ON t1.ID = t2.ID"

Set rst = db.OpenRecordset(sqlString, dbOpenDynaset, dbReadOnly)

' COLUMNS
For i = 1 To rst.Fields.Count
    Worksheets("RESULTS").Cells(1, i) = rst.Fields(i - 1).Name
Next i

' DATA ROWS
Worksheets("RESULTS").Range("A2").CopyFromRecordset rst

rst.Close
db.Close

Set rst = Nothing
Set db = Nothing
Set dbE = Nothing

ADO

Dim conn As Object, rst As Object, fld As Object
Dim strConnection As String, strSQL As String
Dim i As Integer

Set conn = CreateObject("ADODB.Connection")
Set rst = CreateObject("ADODB.Recordset")

' OPEN DB CONNECTION
strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" _
                  & "Data Source='C:\Path\To\FileOne.xlsm';" _
                  & "Extended Properties=""Excel 12.0 Xml;HDR=YES;"";"        

conn.Open strConnection

' OPEN QUERY RECORDSET
strSQL = " SELECT * FROM [TAB$] t1" _
            & " INNER JOIN (SELECT * FROM" _
            & " [Excel 12.0 Xml;HDR=Yes;Database=C:\Path\To\FileTwo.xlsm].[TAB$]) t2" _
            & " ON t1.ID = t2.ID"

rst.Open strSQL, conn

' COLUMNS
For i = 1 To rst.Fields.Count
     Worksheets("RESULTS").Cells(1, i) = rst.Fields(i - 1).Name
Next i

' DATA ROWS
Worksheets("RESULTS").Range("A2").CopyFromRecordset rst

rst.Close
conn.Close

Set rst = Nothing
Set conn = Nothing

使用 VBA-Excel 进行跨多个数据库的 SQL 查询

Using VBA-Excel for an SQL query across multiple databases

sql

excel

vba

dao

data-access-object