如何读取从 iDTCPServer 发送的内存流中的非拉丁字符？

Question

我有这段代码可以插入一些 none 拉丁字符，然后将它从 IDTCPserver 发送到 idTcpclient

LVU := TStringList.Create;
LVU.Add('مرحبا');
try

  if (LVU.Count > 0) then
  begin
    memorylist := TMemoryStream.Create;
    try
      LVU.SaveToStream(memorylist);
      memorylist.Position := 0;
      AContext.Connection.IOHandler.DefStringEncoding := IndyTextEncoding_UTF8;
      AContext.Connection.IOHandler.LargeStream := true;
      AContext.Connection.IOHandler.Write(memorylist, 0, true);
    finally
      memorylist.Free;
    end;
  end;
finally
  LVU.Free;
end;

但是当客户端收到它时，它会将 ms 中的文本接收为 '????????'可能是什么问题？我已经将连接编码设置为 utf8

我运行这个服务器在 Ubuntu。当我在 windows 上尝试服务器时，我正常收到文本。

这就是我在客户端读取流的方式

FMSFROMCALL := TMemoryStream.Create;
FTCP.Socket.LargeStream := True;
FTCP.Socket.ReadStream(FMSFROMCALL, -1, false);
FMSFROMCALL.Position := 0;

Answer 1

您对 DefStringEncoding 的分配不适用于 TIdIOHandler.Write(TStream) 方法。它仅适用于在字符串 <-> 字节之间进行转换的 IOHandler 方法，但是您的 TStream 已经是原始字节，因此不涉及字符串转换。

要执行您正在尝试的操作，您需要将 TEncoding.UTF8 传递给 TStringList.SaveToStream() 方法：

LVU := TStringList.Create;
try
  LVU.Add('مرحبا');
  memorylist := TMemoryStream.Create;
  try
    LVU.SaveToStream(memorylist, TEncoding.UTF8);
    memorylist.Position := 0;
    AContext.Connection.IOHandler.LargeStream := true;
    AContext.Connection.IOHandler.Write(memorylist, 0, true);
  finally
    memorylist.Free;
  end;
finally
  LVU.Free;
end;

当您不将编码传递给 SaveToStream() 时，它会使用默认编码进行编码，在您的情况下是不支持阿拉伯语的编码，因此这就是 ??????? 的来源来自.

另一种方法是发送 TIdBytes 而不是 TMemoryStream:

 Bytes := IndyTextEncoding_UTF8.GetBytes('مرحبا');
 AContext.Connection.IOHandler.WriteInt64(Length(Bytes));
 AContext.Connection.IOHandler.Write(Bytes);

或者，只需按原样发送字符串并分配 DefStringEncoding：

s := 'مرحبا';
AContext.Connection.IOHandler.DefStringEncoding := IndyTextEncoding_UTF8;
AContext.Connection.IOHandler.WriteInt64(IndyTextEncoding_UTF8.GetByteCount(s));
AContext.Connection.IOHandler.Write(s);

如何读取从 iDTCPServer 发送的内存流中的非拉丁字符？

how to read non Latin Charactes inside memory stream that sent from iDTCPServer?

delphi

indy10

delphi-xe8