Stata：具有多个轴的图例项的顺序

Question

我正在尝试使用 twoway 同时绘制两个轴的图形。一个轴使用变量 route 来替换通常使用 mlabel 和 msymbol(none) 的符号。另一个轴在绘图区域中不需要特定标签，但理想情况下应在图例中键入 "Incr. Dose"。

使用 legend(order) 规范创建图例标签时会出现意外结果。编码的图例将第二个轴的符号作为第 3 个有序图例项。我希望代码将第二个轴的符号放置为第 5 个项目。可以通过为未使用的第 5 个 route 添加虚拟类别并使用图形编辑器手动移动符号来解决此问题。我想知道为什么 legend(order) 选项会这样，是否与 mlabel 或 msymbol(none) 有一些交互，以及是否有编码解决方案可用于重复应用。

*create data
clear 
set seed 42
set obs 50

gen cuml_dose = rnormal(0,1) *10 + 100
sort cuml_dose
gen interval = [_n] 
gen id = 1
gen incr_dose =0
replace incr_dose = cuml_dose[_n+1] - cuml_dose if [_n] > 1
gen route = rpoisson(1)
tab route,m

*create problem graph
sort interval
twoway  scatter cuml_dose interval, mlabel(route) msymbol(none) yaxis(1) || ///
    scatter incr_dose interval,  yaxis(2) ///
    legend(on) legend(order(0 "0=oral" 1 "1=IV" 2 "2=IM" 3 "3=patch"))

*partial solution
twoway  scatter cuml_dose interval, mlabel(route) msymbol(none) yaxis(1) || ///
    scatter incr_dose interval,  yaxis(2) ///
    legend(on) legend(order(0 "0=oral" 1 "1=IV" 2 "2=IM" 3 "3=patch" 4 "Incr. dose"))

Answer 1

感谢您提供独立的示例。

考虑

scatter cuml_dose interval, mlabel(route) ms(none) yaxis(1) /// 
|| scatter incr_dose interval, yaxis(2) ///
legend(on order(- "0 = Oral" - "1 = IV" - "2 = IM" - "3 = patch" 2 "Incr. dose"))

在你的最后一张图表中，

cuml_dose 是绘制的第一个变量：您使用具有多个不同值的标记标签这一事实与计数无关。所以，它不对应于 0 到 3。令我惊讶的是 order() 中允许引用 0。最重要的是，标记标签只是文本，graph 不关心除了按照指示显示文本之外的文本内容。
incr_dose 是绘制的第二个变量：因此使用 order(2 ... )。
您可以使用破折号语法任意添加到图例中，如上。
我看不出在这里使用两个轴对定义图例有任何问题。我们只是计算在任何 y 轴上绘制的内容。

底线：按照在语法中提及变量的顺序计算在任何 y 轴上绘制的内容。

Stata：具有多个轴的图例项的顺序

Stata: Order of legend items with multiple axes

graph

stata

legend-properties

multiple-axes