GHC.Generics 示例不起作用

Question

我正在尝试让 GHC.Generics 中描述的通用二进制编码 class 的示例实现正常工作，但是当我尝试编译它时，出现以下代码，但出现错误。

import GHC.Generics

class Encode' f where
  encode' :: f p -> [Bool]

instance Encode' V1 where
  encode' x = undefined

instance Encode' U1 where
  encode' U1 = []

instance (Encode' f, Encode' g) => Encode' (f :+: g) where
  encode' (L1 x) = False : encode' x
  encode' (R1 x) = True  : encode' x

instance (Encode' f, Encode' g) => Encode' (f :*: g) where
  encode' (x :*: y) = encode' x ++ encode' y

instance (Encode c) => Encode' (K1 i c) where
  encode' (K1 x) = encode x

instance (Encode' f) => Encode' (M1 i t f) where
  encode' (M1 x) = encode' x

class Encode a where
  encode :: a -> [Bool]
  default encode :: (Generic a) => a -> [Bool]
  encode x = encode' (from x)

GHC 抱怨：

Could not deduce (Encode' (Rep a)) arising from a use of ‘encode'’
from the context (Encode a)
  bound by the class declaration for ‘Encode’
  ...
or from (Generic a)
  bound by the type signature for encode :: Generic a => a -> [Bool]
  ...
In the expression: encode' (from x)
In an equation for ‘encode’: encode x = encode' (from x)

我错过了什么？

Answer 1

并非 Generic 的所有内容都可以由 encode' 编码。只有那些既是 Generic 又具有表示 Rep a 且具有 Encode' 实例的事物才能由通用 encode' 编码。编译器不知道（也不能知道）Generic 的 Rep 没有被 Encode' 实例覆盖。 Generic 实例的作者可以为他们的 Rep 使用一个甚至不存在的类型。

您需要将请求的 Encode' (Rep a) 约束添加到 default encode 的上下文中。

default encode :: (Generic a, Encode' (Rep a)) => a -> [Bool]

GHC.Generics 示例不起作用

GHC.Generics example doesn't work

generics

haskell