如何在不覆盖 parent 函数的情况下扩展 application.cfc？

Question

我在网上做了一些搜索，看看是否可以这样做，但没有找到任何说可以的东西。我在根目录下有一个 application.cfc，并且有几个子文件夹，我希望它们的功能相同，只有细微差别。例如，root 的 cfc 在 onRequestStart() 中有一个函数，它包含一个函数来确定被调用模板的相对根路径（即，它应该是“../”还是“../../”等，参见 http://www.bennadel.com/blog/1655-ask-ben-dynamic-web-root-and-site-url-calculations-in-application-cfc.htm).

我希望在所有子文件夹的所有页面上运行，但在一个子文件夹中，我还想运行每个请求的安全方案，检查用户是否具有有效权限查看该子文件夹中的页面。如果我在该子文件夹中创建一个 application.cfc 以在根目录下扩展 cfc，那么我放置在那里的任何 onRequestStart() 函数都将覆盖 parent 的 onRequestStart()。

现在，我想出使 child 的 onRequestStart() "the same as the parent's, with just a little extra" 的唯一方法是将 parent cfc 的 onRequestStart() 复制到 child，并在其中添加我的额外安全代码。但是，这样做会搞砸查找页面的相对 webroot 路径的功能。对于该子文件夹中的页面，“../../”将相对于子文件夹中的 application.cfc，而不是相对于根目录中的 parent，这正是我们所希望的。

我的变通方法是将代码放入 parent cfc 的 onRequestStart():

<cfif cgi.script_name CONTAINS "/mySubFolder/">
   (Test the logged-in user's session.roleId; if test fails, cflocation to page that reads "you don't have permissions to view")
</cfif>

并且基本上对任何其他子文件夹或子子文件夹执行相同的操作，我希望为该子文件夹及其任何后代文件夹添加运行代码。这在这个特定的网站上是可以的，因为它不是那么大，但我看到这对于一个更大的网站来说会变得非常混乱。有更好的方法吗？

Answer 1

您的 Google-foo 一定让您失望了 ;) Ben Nadel 举了一个您正在尝试做的事的例子。基本上，您不需要从继承的 Application.cfc 复制函数，您只需要使用 SUPER 范围调用它（调用它）。

这是 Ben 文章的 link - Ask Ben: Extending Application.cfc And OnRequestStart() With SUPER。来自那篇文章：

I have one word for you: SUPER. The SUPER scope is created when one ColdFusion component extends another one. It is available to the extending component and gives access from the extending component up into the extended component, sometimes referred to as the "base component" or "super component." The SUPER scope not only allows us to get access to values in the super component (which isn't necessary since those values are also available in the extending component), but more importantly, it allows us to execute functions in the super component even when those functions are being overridden by the extending ColdFusion component (as they will be in our demo).

To leverage this and pull in the configuration data that you have in your root Application.cfc ColdFusion component, we are going to use the SUPER scope to invoke the OnRequestStart() event method of the root Application.cfc from the sub Application.cfc. But first, let's take a quick look at the root Application.cfc to make sure we are all on the same page:

我不想在这里复制整篇文章，但他继续展示示例并解释正在发生的事情。我绝对推荐阅读他的整篇文章。

这是他的示例 Application.cfc 使用 SUPER 范围：

<cfcomponent
    output="false"
    extends="personal.ben......app_extend2.Application"
    hint="Secondary application event handler.">

    <cffunction
    name="OnRequestStart"
    access="public"
    returntype="boolean"
    output="false"
    hint="Hanldes pre-page processing for each request.">

    <!--- Define arguments. --->
    <cfargument
        name="Page"
        type="string"
        required="true"
        hint="The template requested by the user."
        />

    <!---
        Since this application is extending the root
        Application.cfc, let's leverage the pre-processing
        power of the root OnRequestStart(). Check to see
        what value (true/false) that the root application
        would have returned for this request.
        By calling SUPER.OnRequestStart( Page ), we are
        giving the root application a chance to run logic
        on the page request. **Remember that the
        OnRequestStart() method can return false to kill the
        current page request. Therefore, we have to check to
        see what value would be returned and honor that.
    --->
    <cfif SUPER.OnRequestStart( ARGUMENTS.Page )>

        <!--- Store the sub root directory folder. --->
        <cfset REQUEST.SubDirectory = GetDirectoryFromPath(
        GetCurrentTemplatePath()
        ) />

        <!--- Return out. --->
        <cfreturn true />

    <cfelse>

        <!---
        The root application returned false for this
        page request. Therefore, we want to return
        false to honor that logic.
        --->
        <cfreturn false />

    </cfif>
    </cffunction>

</cfcomponent>

Answer 2

是的，我在 Google 上搜索了 "application.cfc"、"child"、"extends" 和 "subfolder" 的变体，Ben 的几篇博客文章位于顶部结果，但不是那个。

对于寻找相同答案的其他人应该添加的一件事 -- Ben 在其他地方解释说，当为 child cfc 的 cfcomponent 标签添加 "extends" 属性时，CF 不会不要让你简单地使用 "extends='Application'"，因为它首先在 child 自己的文件夹中查找名为 "application.cfc" 的文件，找到它，然后抛出一个错误说 cfc 无法扩展本身。

解决这个问题非常简单 -- Ben 继续解释说您只需要在根目录下创建一个 cfc，名称不是 "application.cfc"，扩展 application.cfc根。它本质上是空的，有 none 个自己的函数或变量。因此，您在根目录下创建一个名为 "applicationProxy.cfc"（或您喜欢的任何名称）的 cfc，然后将以下代码放入其中：

<cfcomponent displayName="applicationProxy" extends="Application"></cfcomponent>

然后在您的 child application.cfc 中，您只需使用：

<cfcomponent extends='applicationProxy'...

如何在不覆盖 parent 函数的情况下扩展 application.cfc？

How to extend application.cfc without overwriting parent functions?

coldfusion

application.cfc