Indy 错误 10038 "Socket operation on non-socket" 闲置 61 秒后

Question

我想从 FTP 服务器下载一些大文件 (GB)。第一个文件的下载始终有效。然后在尝试获取第二个文件时，我得到：

"Socket Error # 10038. Socket operation on non-socket."

错误在 'Get'。在 'Get' 之后，我看到了这些消息（通过 FTP 状态事件）：

   Starting FTP transfer
   Disconnecting.
   Disconnected.

代码是这样的：

{pseudo-code}
for 1 to AllFiles do 
 begin 
   if Connect2FTP then 
    begin
     FTP.Get(Name, GzFile, TRUE, FALSE);  <--- Socket operation on non-socket" error (I also get EIdConnClosedGracefully 'Connection Closed Gracefully' in IDE, F9 will resume execution without problems, but this is OK)
     Unpack(GzFile); <--- this takes more than 60 seconds
    end;
 end;
if FTP.Connected
then FTP.Disconnect;

--

function Connect2FTP(FTP: TIdFTP; RemoteFolder: string; Log: TRichLog): Boolean;      
begin
 Result:= FTP.Connected;
 if NOT Result then
  begin         { We are already connected }
   FTP.Host    := MyFTP;
   FTP.Username:= usr;
   FTP.Password:= psw;

   TRY
    FTP.Connect;
   EXCEPT
    on E: Exception DO

   Result:= FTP.Connected;
   if Result then FTP.ChangeDir(RemoteFolder); 
  end;
end;

完整代码在这里：http://pastebin.com/RScj86R8 (PAS) or here https://ufile.io/26b54 (ZIP)

我认为问题是在调用 'Unpack' 之后出现的，这需要几分钟时间。

更新：已确认：调用'Unpack'后出现问题。我删除了电话，一切都很好。在下载之间暂停（睡眠或断点）程序一段时间（我认为超过 60 秒）会产生同样的问题。

Answer 1

FTP 使用多个套接字连接，一个用于 commands/responses，每个传输使用单独的连接。

套接字错误的最可能原因是 FTP-不知道 proxy/router/firewall 位于 TIdFTP 和 FTP 服务器之间，在短时间不活动。在 Unpack()（或手动暂停）期间，没有 commands/responses 在命令连接上传输，它处于空闲状态，因此可能会因此类 proxy/router/firewall 超时而关闭.

在传输过程中，命令连接处于空闲状态，没有 FTP commands/responses 在其上传输（除非您中止传输），直到传输完成。 FTP-不知道 proxy/router/firewall 可能会在此期间过早地关闭命令连接。

为了避免这种情况，TIdFTP 有一个 NATKeepAlive 属性可以在命令连接处于空闲状态时启用 TCP 保持活动状态。这通常可以防止过早关闭。

但是，当没有传输正在进行时，如果 NATKeepAlive.UseKeepAlive 为 True，TIdFTP 将禁用命令连接上的 TCP 保持活动。 TIdFTP 仅在传输期间使用 TCP 保持连接，假设您不会在 FTP 命令之间执行长时间延迟。如果您需要延迟一段时间，请关闭 FTP 连接，或定期发送 FTP 命令（例如在 timer/thread 中调用 TIdFTP.Noop()）。

或者，您可以尝试在连接到服务器后手动启用 TCP keep-alives，并将 NATKeepAlive.UseKeepAlive 设置为 False 这样 TIdFTP 就不会在每次传输后自动禁用 keep-alives，例如:

function Connect2FTP(FTP: TIdFTP; RemoteFolder: string; Log: TRichLog): Boolean;      
begin
  Result := FTP.Connected;
  if not Result then
  begin         { We are not already connected }
    FTP.Host    := MyFTP;
    FTP.Username:= usr;
    FTP.Password:= psw;

    try
      FTP.Connect;
      try
        FTP.ChangeDir(RemoteFolder); 

        // send a TCP keep-alive every 5 seconds after being idle for 10 seconds
        FTP.NATKeepAlive.UseKeepAlive := False; // False by default, but just in case...
        FTP.Socket.Binding.SetKeepAliveValues(True, 10000, 5000);
      except
        FTP.Disconnect(False);
        raise;
      end;
    except
      Exit;
    end;

    Result := True;
  end;
end;

请注意，虽然大多数平台支持在每个连接的基础上启用 TCP 保持活动（保持活动是 TCP 规范的一部分），但设置保持活动间隔是特定于平台的。目前，Indy 支持将间隔设置为：

Windows 2000+ 和 WinCE 4.x+，适用于 Win32 和 .NET
Linux，在 Kylix 中使用 Indy 时
Unix/Linux 和 NetBSD，当在 FreePascal 中使用 Indy 时。

否则，将使用 OS 默认间隔，根据 OS 配置，对于这种情况，该值可能太大也可能不会太大。

目前，在 Delphi FireMonkey 中无法自定义间隔，Windows.

除外

如果特定平台支持设置自定义 TCP 保持活动间隔，但 Indy 未在 SetKeepAliveValues() 中实现它们，您可以使用 TIdFTP.Socket.Binding.SetSockOpt() 来根据需要手动设置值。许多平台确实支持 TCP_KEEPIDLE/TCP_KEEPINTVL 或等效的套接字选项。

Indy 错误 10038 "Socket operation on non-socket" 闲置 61 秒后

Indy error 10038 "Socket operation on non-socket" after 61 seconds of inactivity

delphi

ftp

indy

indy10

delphi-xe7