获取 TGridPanel 中点击控件的列索引

Question

我正在使用 TGridPanel 来固定一些面板。在设计时，我将网格面板设置为 1 行和 5 列。

我可以使用这段代码向网格添加一个面板，效果很好：

procedure TForm6.AddPanelToGrid(const ACaption: string);
var
  pnl: TPanel;
begin
  pnl := TPanel.Create(gpOne);
  pnl.Caption := ACaption;
  pnl.Parent := gpOne;
  pnl.Name := 'pnlName' + ACaption;
  pnl.OnClick := gpOne.OnClick;
  pnl.ParentBackground := false;
  pnl.ParentColor := false;
  pnl.Color := clLime;
  pnl.Font.Size := 14;
  gpOne.ControlCollection.AddControl(pnl);
  pnl.Height := pnl.Width;
end;

我想要做的是当我点击它时从网格中删除一个 TPanel（这就是为什么我在上面的代码中将点击处理程序设置为网格面板的处理程序）。

在那个点击处理程序中，我这样做了，几乎可以工作：

procedure TForm6.gpOneClick(Sender: TObject);
begin
  if not (sender is TPanel) then exit;

  gpOne.ControlCollection.RemoveControl(Sender as TPanel);
  (Sender as TPanel).Free;

  gpOne.UpdateControlsColumn( 0 );  <<<-------
  gpOne.UpdateControlsRow(0);

  gpOne.Refresh();
end;

使用 UpdateControlColumn() 的参数会导致网格中面板的顺序发生变化 - 第一个和第二个交换位置。

我可以通过将列索引添加到面板的标记属性来解决这个问题，然后将其传递给 UpdateControlColumn()。这样就可以了，但是一旦面板被移除，更高的标签号就不再有效——面板已经移动了列。

那么，如何从 OnClick 处理程序中获取面板所在的列？

我正在使用 Delphi 10.1 Berlin - 如果这有什么不同的话。

为了对此进行测试，我启动了一个新项目，添加了一个 TGridPanel，将其设置为具有 1 行和 5 个等宽的列。我添加了 6 个 TButton 控件并使用以下代码为每个控件创建了一个 OnClick 处理程序：

AddPanelToGrid('One');  // changing the string for each button.

单击几个按钮添加一些面板，然后单击面板将其删除。

Answer 1

TCustomGridPanel 有一对有用的函数，CellIndexToCell() 和 CellToCellIndex，但它们不是 public，因此不能直接从 TGridPanel 访问。

为了使它们可用，请重新声明 TGridPanel，如下所示：

type
  TGridPanel = class(Vcl.ExtCtrls.TGridPanel)  // add this
  end;                                         // -"-
  TForm27 = class(TForm)
    Button1: TButton;
    gpOne: TGridPanel;
    ...
  end;

然后为行和列添加 r 和 c 变量，添加对 CellIndexToCell() 的调用并使用 c 作为 UpdateControlsColumn 的参数：

procedure TForm27.gpOneClick(Sender: TObject);
var
  r, c: integer;
begin
  if not (sender is TPanel) then exit;

  gpOne.CellIndexToCell(gpOne.ControlCollection.IndexOf(Sender as TPanel), c, r); // add this

  gpOne.ControlCollection.RemoveControl(Sender as TPanel);
  (Sender as TPanel).Free;

  gpOne.UpdateControlsColumn( c );  // <<<-------
  gpOne.UpdateControlsRow(0);

  gpOne.Refresh();
end;

并遵循 Remy Lebeau 关于释放面板的建议。（我刚刚注意到他的评论）。

如果您还没有看过，您可能还想看看 TFlowPanel 及其 FlowStyle 属性。 TflowPanel 如果您使用多行，则删除后重新排序更可预测，但这当然取决于您的需要。

获取 TGridPanel 中点击控件的列索引

Getting column index of a clicked control in TGridPanel

delphi

vcl

tgridpanel

delphi-10.1-berlin