XSLT 展平 XML（具有重复元素）

Question

我需要使用 XSLT 将 XML 展平。下面是 XML

<Parent>
   <Child type="X">
      <data value="1" />
      <data value="2" />
      <data value="3" />
   </Child>
   <Child type="Y">
      <data value="5" />
      <data value="6" />
      <data value="7" />
      <data value="8" />
   </Child>
</Parent>

期望的输出

<Parent>
   <Child type="X" data1_value="1" data2_value="2" data3_value="3"/>
   <Child type="Y" data1_value="5" data2_value="6" data3_value="7" data4_value="8"/>
</Parent>

Answer 1

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:output method="xml" encoding="utf-8" indent="yes" />
   <xsl:template match="/">
      <Parent>
         <xsl:for-each select="/Parent/Child">
            <Child type="{@type}">
               <xsl:for-each select="data">
                  <xsl:attribute name="data{position()}_value">
                     <xsl:value-of select="@value" />
                  </xsl:attribute>
               </xsl:for-each>
            </Child>
         </xsl:for-each>
      </Parent>
   </xsl:template>
</xsl:stylesheet>

Answer 2

您没有花太多精力来定义场景的细节，但这应该适用于该输入：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*" />

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/*/*/*">
    <xsl:variable name="name" select="local-name()" />
    <xsl:variable name="num">
      <xsl:number count="*[local-name() = $name]"/>
    </xsl:variable>

    <xsl:apply-templates select="@*">
      <xsl:with-param name="prefix" select="concat(local-name(), $num)" />
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="/*/*/*/@*">
    <xsl:param name="prefix" />

    <xsl:attribute name="{concat($prefix, '_', local-name())}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

当您的示例输入运行时，结果为：

<Parent>
  <Child type="X" data1_value="1" data2_value="2" data3_value="3" />
  <Child type="Y" data1_value="5" data2_value="6" data3_value="7" data4_value="8" />
</Parent>

如果有不同名称的孙元素，像这样：

<Parent>
   <Child type="X">
      <data value="1" />
      <data value="2" />
      <data value="3" />
   </Child>
   <Child type="Y">
      <data value="5" />
      <mydata value="6" />
      <data value="7" />
      <mydata value="8" />
   </Child>
</Parent>

然后每个不同的名称将被单独编号（我认为这比将所有名称一起编号更可取）：

<Parent>
  <Child type="X" data1_value="1" data2_value="2" data3_value="3" />
  <Child type="Y" data1_value="5" mydata1_value="6" data2_value="7" mydata2_value="8" />
</Parent>

XSLT 展平 XML（具有重复元素）

XSLT to flatten XML(has repeating elements)

xml

xslt