如何在我的语法中执行操作优先级 (+ * - /)？

Question

我使用 antlr 4 定义了我自己的语法，我想根据操作的优先级构建树 true (+ * - /) ....

我发现有关执行操作优先级 (* +) 的示例工作正常...

我尝试对其进行编辑以添加操作优先级 (- /)，但我失败了 :(

操作优先级 (+ *) 的语法是：

 println:PRINTLN  expression SEMICOLON {System.out.println($expression.value);};
 expression returns [Object value]:
  t1=factor {$value=(int)$t1.value;}
  (PLUS t2=factor{$value=(int)$value+(int)$t2.value;})*;

  factor returns [Object value]: t1=term {$value=(int)$t1.value;}
  (MULT t2=term{$value=(int)$value*(int)$t2.value;})*;

 term returns [Object value]:
  NUMBER {$value=Integer.parseInt($NUMBER.text);}
   | ID {$value=symbolTable.get($value=$ID.text);}
   | PAR_OPEN expression {$value=$expression.value;} PAR_CLOSE
   ;
MULT :'*';
PLUS :'+';

MINUS:'-';
DIV:'/' ;

如何向它们添加操作优先级 (- /)？

Answer 1

您通常通过定义 expression、term 和 factor 产生式规则来解决此问题。这是实现一元 + 和一元 - 的语法（在 EBNF 中指定），以及 4 个二元算术运算符，加上括号：

start ::= expression
expression ::= term (('+' term) | ('-' term))*
term ::= factor (('*' factor) | ('/' factor))*
factor :: = (number | group | '-' factor | '+' factor) 
group ::= '(' expression ')'

其中 number 是数字文字。

Answer 2

在 ANTLR3（和 ANTLR4）中，* 和 / 可以被赋予比 + 和 - 更高的优先级，如下所示：

println
 : PRINTLN  expression SEMICOLON
 ;

expression
 : factor ( PLUS factor 
          | MINUS factor
          )*
 ;

factor
 : term ( MULT term
        | DIV term
        )*
 ;

term
 : NUMBER
 | ID
 | PAR_OPEN expression PAR_CLOSE
 ;

但是在 ANTLR4 中，这也可以工作：

println
 : PRINTLN  expression SEMICOLON
 ;

expression
 : NUMBER
 | ID
 | PAR_OPEN expression PAR_CLOSE
 | expression ( MULT | DIV ) expression   // higher precedence
 | expression ( PLUS | MINUS ) expression // lower precedence
 ;

如何在我的语法中执行操作优先级 (+ * - /)？

How to do Priority of Operations (+ * - /) in my grammars?

context-free-grammar

antlr4