如何设置%Dictionary.StorageSQLMapDataDefinition.RetrievalCode？

Question

我该怎么做：

<Data name="hyperlink">
<RetrievalCode>
<![CDATA[set res=""
    set colId=""
    for
    {
        set colId = $order( ^ohtest("mltab","main","Dta",{L4},colId) )
        quit:(colId = "")

        set indexTab = $g(^ohtest("mltab","main","Dta",{L4},colId,"Index"))
        if indexTab'="" {
            set res = res_"<hyperlinkIndexTab><colId>"_colId_"</colId><iTab>"_indexTab_"</iTab></hyperlinkIndexTab>"
        }
    }
    s {hyperlink}=res]]></RetrievalCode>
</Data>

以编程方式？

我有：

            set global = "^ohtest"
            set iTab="main"

            //hyperlink
            set storData = ##class(%Dictionary.StorageSQLMapDataDefinition).%New()
            set storData.Name = "hyperlink"
            set storData.RetrievalCode = "<![CDATA[set res="""" set colId="""" for{set colId = $order( "_global_"(""mltab"","_iTab_",""Dta"",{L4},colId) ) quit:(colId = """") set indexTab = $g("_global_"(""mltab"","_iTab_",""Dta"",{L4},colId,""Index"")) if indexTab'="""" {set res = res_""<hyperlinkIndexTab><colId>""_colId_""</colId><iTab>""_indexTab_""</iTab></hyperlinkIndexTab>""}} s {hyperlink}=res]]>"
            do storMap.Data.Insert(storData)

但是没用。如何让生成上面提供的代码？

Answer 1

您的第一个问题是，将 CDATA 声明放入代码中。 Caché 会在没有您的情况下添加它，然后您将不带引号的 iTab 添加。

    set global = "^ohtest"
    set iTab="main"

    set data=##class(%Dictionary.StorageSQLMapDataDefinition).%New()
    set data.Name="hyperlink"
    set code=""
    set code=code_"set res="""""_$c(13,10)
    set code=code_"set colId="""""_$c(13,10)
    set code=code_"for"_$c(13,10)
    set code=code_"{"_$c(13,10)
    set code=code_"  set colId = $order( "_global_"(""mltab"","""_iTab_""",""Dta"",{L4},colId) )"_$c(13,10)
    set code=code_"  quit:(colId = """")"_$c(13,10)
    set code=code_"  set indexTab = $g("_global_"(""mltab"","""_iTab_""",""Dta"",{L4},colId,""Index""))"_$c(13,10)
    set code=code_"  if indexTab'="""" {"_$c(13,10)
    set code=code_"    set res = res_""<hyperlinkIndexTab><colId>""_colId_""</colId><iTab>""_indexTab_""</iTab></hyperlinkIndexTab>"""_$c(13,10)
    set code=code_"  }"_$c(13,10)
    set code=code_"}"_$c(13,10)
    set code=code_"s {hyperlink}=res"_$c(13,10)
    set data.RetrievalCode=code
    do storMap.Data.Insert(data)

如何设置%Dictionary.StorageSQLMapDataDefinition.RetrievalCode？

How to set %Dictionary.StorageSQLMapDataDefinition.RetrievalCode?

intersystems

objectscript