在 Coq 中证明上推惰性列表的相等性

Question

我正在试验 Coq Coinductive 类型。我使用来自 Coq'Art 书（第 13.1.4 节）的惰性列表类型：

Set Implicit Arguments.

CoInductive LList (A:Set) : Set :=
| LNil : LList A
| LCons : A -> LList A -> LList A.
Implicit Arguments LNil [A].

CoFixpoint LAppend (A:Set) (u v:LList A) : LList A :=
  match u with
  | LNil => v
  | LCons a u' => LCons a (LAppend u' v)
  end.

为了匹配守卫条件，我还使用了本书中的以下分解函数：

Definition LList_decomp (A:Set) (l:LList A) : LList A :=
  match l with
  | LNil => LNil
  | LCons a l' => LCons a l'
  end.


Lemma LList_decompose : forall (A:Set) (l:LList A), l = LList_decomp l.
Proof.
 intros.
 case l.
 simpl.
 reflexivity.
 intros.
 simpl. 
 reflexivity.
Qed.

LNil是左中立的引理很容易证明：

Lemma LAppend_LNil : forall (A:Set) (v:LList A), LAppend LNil v = v.
Proof.
 intros A v.
 rewrite LList_decompose with (l:= LAppend LNil v).
 case v.
 simpl.
 reflexivity.
 intros.
 simpl.
 reflexivity.
Qed.

但我在证明 LNil 也是右中立时陷入困境：

Lemma LAppend_v_LNil : forall (A:Set) (v:LList A), LAppend v LNil = v.

在亚瑟的回答后，我尝试了新的平等：

Lemma LAppend_v_LNil : forall (A:Set) (v:LList A), LListEq  (LAppend v LNil)  v.
Proof.
 intros.
 cofix.
 destruct v.
 rewrite LAppend_LNil.
 apply LNilEq.

我卡在这里了。 Coq 的回答是：

1 subgoal
A : Set
a : A
v : LList A
LAppend_v_LNil : LListEq (LAppend (LCons a v) LNil) (LCons a v)
______________________________________(1/1)
LListEq (LAppend (LCons a v) LNil) (LCons a v)

在 Eponier 的回答之后，我想通过引入外延公理来给它最后的润色：

Axiom LList_ext: forall (A:Set)(l1 l2: LList A), (LListEq l1 l2 ) -> l1 = l2.

有了这个公理，我得到了引理的最终切割：

Lemma LAppend_v_LNil : forall (A:Set) (v:LList A), (LAppend v LNil) = v.
Proof.
 intros.
 apply LList_ext.
 revert v.
   cofix.
   intros.
   destruct v. Guarded. (* now we can safely destruct v *)
   - rewrite LAppend_LNil.
     constructor.
   - rewrite (LList_decompose (LAppend _ _)).
     simpl. constructor. apply LAppend_v_LNil.
Qed.

现在，这是我对该主题的最后一个问题：

这样的公理是否已经存在于某些 Coq 库中？
该公理与 Coq 一致吗？
与 Coq 的哪些标准公理（例如 classic、UIP、fun ext、Streicher K）不一致？

Answer 1

您猜对了：就像函数一样，Coq 的通用相等性概念太弱，无法用于大多数余归类型。如果你想证明你的结果，你需要将 eq 替换为列表相等的共同归纳概念；例如：

CoInductive LListEq (A:Set) : LList A -> LList A -> Prop :=
| LNilEq : LListEq A LNil LNil
| LConsEq x lst1 lst2 : LListEq A lst1 lst2 -> 
  LListEq A (LCons x lst1) (LCons x lst2).

操作无限对象是 Coq 中的一个庞大主题。如果您想了解更多信息，Adam Chlipala 的 CPDT 有完整的chapter coinduction。

Answer 2

一个简单的规则是在你的证明中尽快使用 cofix。

实际上，在您 LAppend_v_LNil 的证明中，在 destruct v 处已经违反了守卫条件。您可以使用命令 Guarded 来检查这个事实，这有助于在证明结束之前测试是否所有使用共同归纳假设都是合法的。

Lemma LAppend_v_LNil : forall (A:Set) (v:LList A), LListEq  (LAppend v LNil)  v.
  intros.
  cofix.
  destruct v. Fail Guarded.
Abort.

你实际上应该交换 intros 和 cofix。从那里，证明并不困难。

编辑：这是完整的解决方案。

Lemma LAppend_v_LNil : forall (A:Set) (v:LList A), LListEq (LAppend v LNil)  v.
  cofix.
  intros.
  destruct v. Guarded. (* now we can safely destruct v *)
  - rewrite LAppend_LNil.
    constructor.
  - rewrite (LList_decompose (LAppend _ _)).
    simpl. constructor. apply LAppend_v_LNil.
Qed.

在 Coq 中证明上推惰性列表的相等性

Proving equality on coinductive lazy lists in Coq

coq

lazy-sequences

coinduction