vba 列的条件格式

Question

我是 VBA 的新手，所以我遇到了几个问题。

我有一个如下所示的数据集：

我必须将 A 列与 B、C、D、E 和 F 列进行比较，然后在这些条件下为 B:F 列中的单元格字体着色：

如果 A 列中的单元格与 B:F 列中的单元格相同，则将其字体涂成橙色。
如果 A 列中的单元格高于 B:F 列中的单元格，则将其字体涂成红色。
如果 A 列中的单元格低于 B:F 列中的单元格，请将其字体涂成绿色。
如果 A 列与其余列 (B:F) 的绝对差小于 1，则将其字体涂成橙色。

我尝试写了一个简单的宏，除了第 4 个条件外，所有条件都满足。

这是我的尝试。

Sub ConditionalFormating()
Dim i, j, a As Double
    a = 0.99
    i = 2
    j = 2

    For j = 1 To 6     
    For i = 2 To 10

     ActiveSheet.Cells(i, j).Select


   If ActiveSheet.Cells(i, j) - ActiveSheet.Cells(i, 1) >= a Then

    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .Color = RGB(255, 156, 0)
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
   End If


     If ActiveSheet.Cells(i, j) - ActiveSheet.Cells(i, 1) <= a Then

    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .Color = RGB(255, 156, 0)
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
   End If


   If ActiveSheet.Cells(i, j) > ActiveSheet.Cells(i, 1) Then

    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .Color = RGB(0, 255, 0)
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
   End If



    If ActiveSheet.Cells(i, j) < ActiveSheet.Cells(i, 1) Then

    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .Color = RGB(255, 0, 0)
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
   End If

   Next
    Next
End Sub

有人能帮帮我吗？我不明白为什么第 4 个条件不满足，而其他所有条件都满足。

提前致谢！

Answer 1

要为字体着色，您必须使用 Range 的字体属性，例如：Selection.Font.Color=RGB(255,128,0).

Answer 2

您可以试试这个（注释）代码：

Option Explicit

Sub ConditionalFormating()
    Dim cell As Range, cell2 As Range, dataRng As Range
    Dim colOrange As Long, colRed As Long, colGreen As Long, col As Long

    colOrange = RGB(255, 156, 0)
    colRed = RGB(255, 0, 0)
    colGreen = RGB(0, 255, 0)

    With Worksheets("CF") '<--| reference the relevant worksheet (change "CF" to your actual worksheet name)
        Set dataRng = Intersect(.Columns("B:F"), .UsedRange)
        For Each cell In .Range("A2", .Cells(.Rows.Count, 1).End(xlUp)).SpecialCells(xlCellTypeConstants) '<-- loop through its column "A" not empty cells from row 1 down to last not empty one
            If WorksheetFunction.CountA(Intersect(dataRng, cell.EntireRow)) > 0 Then ' if current row has data
                For Each cell2 In Intersect(dataRng, cell.EntireRow).SpecialCells(xlCellTypeConstants) ' loop through current column "A" cell row not empty cells
                    Select Case True '<-- check the current datum against the following conditions
                        Case cell2.Value = cell.Value Or Abs(cell.Value - cell2.Value) < 1 'if current datum equals corresponding value in column "A" or their absolute difference is lower than 1
                            col = colOrange
                        Case cell2.Value < cell.Value 'if current datum is lower then corresponding value in column "A"
                            col = colRed
                        Case cell2.Value > cell.Value  'if current datum is higher then corresponding value in column "A"
                            col = colGreen
                    End Select
                    With cell2.Interior
                        .Pattern = xlSolid
                        .PatternColorIndex = xlAutomatic
                        .Color = col
                        .TintAndShade = 0
                        .PatternTintAndShade = 0
                    End With
                Next cell2
            End If
        Next cell
    End With
End Sub

vba 列的条件格式

vba conditional formatting to columns

excel

vba

conditional-formatting