Lwt and Cohttp: `Fatal error: exception Unix.Unix_error(Unix.ECONNRESET, "read", "")`

Question

我在带有 Cohttp 和 Lwt 的 Ocaml 中有一个简单的 HTTP 服务器。当我运行 wrk 时，应用程序在 wrk 完成后大约有 50% 的时间崩溃。我想崩溃是由意外断开连接引发的。

我在控制台上看到以下错误：

Fatal error: exception Unix.Unix_error(Unix.ECONNRESET, "read", "")
Raised by primitive operation at file "src/unix/lwt_bytes.ml", line 130, characters 42-84
Called from file "src/unix/lwt_unix.ml", line 489, characters 13-24

有什么办法可以防止这种情况发生吗？

我的完整源代码是：

(* server_test.ml *)
open Unix
open Lwt
open Cohttp
open Cohttp_lwt_unix
open Yojson
open Yojson.Basic.Util
open Core.Std

type create = {
username: string;
email: string;
password: string;
} [@@deriving yojson]

let insert coll doc =
    let _id = Core.Std.Uuid.to_string (Uuid.create ()) in
    let uri = Uri.make ~scheme:"http" ~host:"127.0.0.1" ~port:5984 ~path:(coll ^ "/" ^ _id) () in
    Cohttp_lwt_unix.Client.put ~body:(Cohttp_lwt_body.of_string (Yojson.Safe.to_string doc)) uri
    >|= fun (r, _) -> Code.code_of_status @@ Response.status r

let callback _conn req body =
    body |> Cohttp_lwt_body.to_string 
    >>= (fun body -> 
        let mc = Yojson.Safe.from_string body |> create_of_yojson in
        match mc with
        | Ok c -> 
            insert "users" (create_to_yojson c)
            >>= fun status -> print_endline @@ string_of_int status; 
                Server.respond_string ~status:(`Code status) ~body:(string_of_int status) ()
        | _ -> Server.respond_string ~status:`OK ~body: "Not OK" ())

let timeit _conn req body =
    let start = Unix.gettimeofday () in
    callback _conn req body 
    >>= 
    fun result ->
        let finish = Unix.gettimeofday () in
        Lwt_io.printlf "Execution time took %fms" ((finish -. start) *. 1000.0)
        >|= fun _ -> result

let server =
    Server.create ~mode:(`TCP (`Port 8000)) (Server.make timeit ())

let () = ignore (Lwt_main.run server)

谢谢！

Answer 1

您看到的错误是由客户端意外断开连接时引发的未处理异常引起的。相关的异常被传递给 Lwt 的异步异常钩子（http://ocsigen.org/lwt/2.6.0/api/Lwt#VALasync_exception_hook），在 Lwt 的默认情况下，它会打印回溯并退出程序，退出代码为 2.

在 cohttp github 问题跟踪器上正在进行关于此的讨论：https://github.com/mirage/ocaml-cohttp/issues/511

简而言之，如果您为 Lwt 的异步/"background" 线程定义自定义异常处理程序，那么您可以捕获并 ignore/log/handle 客户端错误。在启动 cohttp 服务器之前添加如下内容：

Lwt.async_exception_hook := (function
  | Unix.Unix_error (error, func, arg) ->
    Logs.warn (fun m ->
      m  "Client connection error %s: %s(%S)"
        (Unix.error_message error) func arg
    )
  | exn -> Logs.err (fun m -> m "Unhandled exception: %a" Fmt.exn exn)
);

取自https://github.com/mirage/ocaml-cohttp/issues/511#issuecomment-258510531 and using the logs library to log the event: http://erratique.ch/software/logs

Lwt and Cohttp: `Fatal error: exception Unix.Unix_error(Unix.ECONNRESET, "read", "")`

Lwt and Cohttp: `Fatal error: exception Unix.Unix_error(Unix.ECONNRESET, "read", "")`

ocaml

ocaml-lwt