进行中的数组长度？

Question

给定两个数组，（例如 1,2,3,4,5 和 2,3,1,0）。查找第二个数组中不存在的第一个数组的编号。我如何获得进行中的数组长度 4gl？

Answer 1

要获得列表的长度（列表的项目数），您可以使用 NUM-ENTRIES() 函数。

要知道某个项目是否存在于列表中，您可以使用 LOOKUP() 函数。

所以对于你的例子，你可以这样做：

DEFINE VARIABLE wclist1 AS CHARACTER  NO-UNDO   INITIAL "1,2,3,4,5".
DEFINE VARIABLE wclist2 AS CHARACTER  NO-UNDO   INITIAL "2,3,1,0".

DEFINE VARIABLE wc-list-no-present AS CHARACTER  NO-UNDO.

DEFINE VARIABLE wi-cpt AS INTEGER    NO-UNDO.

/* For each items of list1 */
DO wi-cpt = 1 TO NUM-ENTRIES(wclist1, ","):

    /* Test if the item is in list 2 */
    IF LOOKUP(ENTRY(wi-cpt, wclist1, ","), wclist2, ",") = 0 
    THEN
        wc-list-no-present = wc-list-no-present + "," + ENTRY(wi-cpt, wclist1, ",").
END.

/* TRIM is to remove the first "," */
DISPLAY TRIM(wc-list-no-present, ",").

Answer 2

如果所讨论的对象是 ARRAY 而不是 LIST，您可以使用 EXTENT() 函数来确定元素的数量。使用数组：

define variable a1 as integer no-undo extent 5 initial [ 1, 2, 3, 4, 5 ].
define variable a2 as integer no-undo extent 4 initial [ 2, 3, 1, 0 ].

define variable i as integer no-undo.
define variable j as integer no-undo.

define variable ok as logical no-undo.

do i = 1 to extent( a1 ):
  ok = no.
  do j = 1 to extent( a2 ):
    if a1[i] = a2[j] then ok = yes.
  end.
  if ok = no then message a1[i] "is not in a2".
end.

Answer 3

def var a as int extent 5 initial [1,2,3,4,5] no-undo.
def var b as int extent 4 initial [2,3,1,0] no-undo.
def var i as int no-undo.
def var j as int no-undo.

loop:
repeat i = 1 to extent(a):

    repeat j = 1 to extent(b):
        if a[i] = b[j]
        then next loop.
    end.
    Display a[i] "not in b array" format "x(20)".
end.

进行中的数组长度？

Length of Array in progress?

progress-4gl

openedge