如何从维基数据中检索别名

Question

我正在尝试从维基数据中检索一些信息，我发现收集声音的别名很有趣。例如，Francesco Totti 也被称为 il Capitano 或 er Pupone：

我正在尝试使用此 sparql 查询检索所有意甲联赛的足球运动员：

SELECT ?subject ?nomeLabel ?cognomeLabel ?subjectLabel WHERE {
  ?subject wdt:P31 wd:Q5.

  ?subject p:P54 ?team .
  ?team ps:P54 wd:""" + team_code +""" .
  FILTER NOT EXISTS { ?team pq:P582 ?end
    }
OPTIONAL{
  ?subject wdt:P735 ?nome .
  ?subject wdt:P734 ?cognome .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". }
}
ORDER BY (?cognomeLabel)

如何修改我的查询以同时使用别名？谢谢

Answer 1

我尝试过使用各种标签进行查询。仅供罗马使用：

SELECT distinct ?subject ?subjectLabel ?nomeLabel ?cognomeLabel ?nickname ?alternative ?subjectAltLabel WHERE {
  ?subject wdt:P31 wd:Q5.
  ?subject p:P54 ?team .
  ?team ps:P54 wd:Q2739 .
  FILTER NOT EXISTS { ?team pq:P582 ?end . }
  OPTIONAL { ?subject wdt:P735 ?nome . }
  OPTIONAL { ?subject wdt:P734 ?cognome . }
  OPTIONAL { ?subject wdt:P1449 ?nickname . }
  OPTIONAL { ?subject skos:altLabel ?alternative . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en,fr". }
}
ORDER BY (?cognomeLabel)

我觉得P1449属性应该是最适合属性存放一个alias/nickname的，不过足球运动员好像用的不多。我刚刚将 "il Capitano" 添加到 Francesco Totti。除了那个，罗马球员似乎没有其他昵称了。

"Also known as" 标签（在右栏中）不一定是昵称，但可能是拼写变体。

Answer 2

如果有人对所有 return 仅英语 also known as:

的属性感兴趣，则更通用

SELECT ?property ?propertyLabel ?propertyDescription (GROUP_CONCAT(DISTINCT(?altLabel); separator = ", ") AS ?altLabel_list) WHERE {
    ?property a wikibase:Property .
    OPTIONAL { ?property skos:altLabel ?altLabel . FILTER (lang(?altLabel) = "en") }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" .}
 }
GROUP BY ?property ?propertyLabel ?propertyDescription
LIMIT 5000

Answer 3

男演员的另一个更简单的例子 itemAltLabel :

#Male Actors
SELECT ?item ?itemLabel ?itemAltLabel
WHERE 
{
    ?item wdt:P21 wd:Q6581097.
  ?item wdt:P106 wd:Q33999.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

如何从维基数据中检索别名

How to retrieve aliases from wikidata

sparql

wikidata