XSL:FO 每个级别不同的列表项标签

Question

我正在使用 Apache FOP 从我的 Web 应用程序生成 PDF，用户可以在其中使用 CKEditor.

我的问题是用户有时会在（非）有序列表中使用不同级别的缩进，例如：

列表项级别 1
- 列出项目级别 2

CKEditor 在每个级别（或缩进）显示不同的公告，但生成的 PDF 不会，因为我的模板如下所示：

<!-- Lists -->
<xsl:template match="ul|ol" mode="content">
    <xsl:apply-templates select="li" mode="content">
        <xsl:with-param name="ordered">
            <xsl:value-of select="name()='ol'"/>
        </xsl:with-param>
    </xsl:apply-templates>
</xsl:template>

<xsl:template match="li" mode="content">
    <xsl:param name="ordered"/>
    <xsl:variable name="label">
        <xsl:choose>
            <xsl:when test="$ordered='true'">
                <xsl:value-of select="position()"/>
                .
            </xsl:when>
            <xsl:otherwise>
                &#8226;
            </xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <fo:list-block padding-bottom="0pt">
        <fo:list-item>
            <fo:list-item-label>
                <fo:block>
                    <xsl:value-of select="$label"/>
                </fo:block>
            </fo:list-item-label>
            <fo:list-item-body start-indent="body-start()">
                <fo:block>
                    <xsl:apply-templates mode="content"/>
                </fo:block>
            </fo:list-item-body>
        </fo:list-item>
    </fo:list-block>
</xsl:template>

那么如何根据缩进级别设置标签变量呢？

类似于：

第 1 级：•
二级：◦
第 3 级：⁍

提前致谢，~Fabi

编辑：@fafl 建议的解决方案如下所示：

<!-- Lists -->
    <xsl:template match="ul|ol" mode="content">
        <xsl:param name="depth" select="0"/>
        <xsl:apply-templates select="li" mode="content">
            <xsl:with-param name="ordered">
                <xsl:value-of select="name()='ol'"/>
            </xsl:with-param>
            <xsl:with-param name="depth">
                <xsl:value-of select="$depth + 1"/>
            </xsl:with-param>
        </xsl:apply-templates>
    </xsl:template>

    <xsl:template match="li" mode="content">
        <xsl:param name="depth" select="0"/>
        <xsl:param name="ordered"/>
        <xsl:variable name="label">
            <xsl:choose>
                <xsl:when test="$ordered='true'">
                    <xsl:value-of select="position()"/>
                    .
                </xsl:when>
                <xsl:otherwise>
                    <xsl:choose>
                        <xsl:when test="$depth = 1">
                            &#8226; <!--filled circle-->
                        </xsl:when>
                        <xsl:when test="$depth = 2">
                            &#9702; <!--not-filled circle-->
                        </xsl:when>
                        <xsl:otherwise>
                            &#9632; <!--black square -->
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        <fo:list-block padding-bottom="0pt">
            <fo:list-item>
                <fo:list-item-label>
                    <fo:block>
                        <xsl:value-of select="$label"/>
                    </fo:block>
                </fo:list-item-label>
                <fo:list-item-body start-indent="body-start()">
                    <fo:block>
                        <xsl:apply-templates mode="content">
                            <xsl:with-param name="depth">
                                <xsl:value-of select="$depth"/>
                            </xsl:with-param>
                        </xsl:apply-templates>
                    </fo:block>
                </fo:list-item-body>
            </fo:list-item>
        </fo:list-block>
    </xsl:template>

Answer 1

尝试将参数 "depth" 添加到两个模板，默认值为 1。在每次递归调用 "ul|ol" 时将其增加 1。然后您可以在两个模板中查询它。

XSL:FO 每个级别不同的列表项标签

XSL:FO Different list-item-label per level

xslt

pdf-generation

html-lists

apache-fop