PL/SQL: ORA-00932: 数据类型不一致: 预期得到 NUMBER USER_NAME.VARCHAR_ARRAY

Question

下面是我正在创建的一个函数，用于接受 varchar2 项数组和 return 该记录的内部 pk，即每条记录的 NUMBER。我正在努力获得正确的语法，以将 VARCHAR_ARRAY 类型的数组传递给游标中的简单 sql 查询，并 return 类型为 NUMBER_ARRAY 的变量。错误在第 8,42 行，即传递给函数的 FROM table_name WHERE column_name IN VARCHAR_ARRAY。请帮我解决这个错误，因为我正在学习 plsql。

  create or replace TYPE VARCHAR_ARRAY AS VARRAY(1000000) OF VARCHAR2(1000);
   /

  create or replace TYPE NUMBER_ARRAY AS VARRAY(1000000) OF NUMBER;
   /

  create or replace Function GET_PRODUCT_ID_ARR(V_PRODUCT_NUM_ARR IN VARCHAR_ARRAY)
  RETURN NUMBER_ARRAY 
  IS
     product_id_list number_array := number_array(); 
     CURSOR c1
     IS 
     SELECT cat_map_id 
     FROM mn_cat_map WHERE product_num IN (V_PRODUCT_NUM_ARR) and catalog_type = 'INT';
  v_output NUMBER;   
  BEGIN
      OPEN c1; 
      LOOP
          fetch c1 into product_id_list;
          EXIT WHEN c1%notfound;
          product_id_list.extend;
          product_id_list(product_id_list.count)  := v_output;
         dbms_output.put_line('Product ('||v_output ||'):'||product_id_list(v_output));
      END LOOP;
  Close c1;
  RETURN product_id_list;
  END;
  /

Answer 1

有两个问题：

您必须将 varray 转换为 table:

CURSOR c1
IS 
SELECT cat_map_id 
FROM mn_cat_map 
WHERE product_num IN (select column_value from table(V_PRODUCT_NUM_ARR))
  and catalog_type = 'INT';

在fetch之后添加bulk collect:

LOOP
  fetch c1 bulk collect into product_id_list limit 100;
  EXIT WHEN c1%notfound;
  product_id_list.extend;
  product_id_list(product_id_list.count)  := v_output;
  dbms_output.put_line('Product ('||v_output ||'):'||product_id_list(v_output));
  END LOOP;

如果写成limit 100，每次循环会在product_id_list中放入100条记录。您可以省略 limit 子句，在这种情况下，您将一次获取所有记录。

编辑
如何查看结果：

declare 
  myarray varchar_array; 
  my_num_array number_array;
begin 
  myarray := varchar_array(); 
  myarray.extend(2);
  myarray(1) := '151043'; 
  myarray(2) := '2895'; 
  my_num_array := GET_PRODUCT_ID_ARR(myarray);
  for i in 1 .. my_num_array.count loop
    dbms_output.put_line(my_num_array(i)); 
  end loop; 
end;
/

Answer 2

@William 说的是真的。 VARRAY(1000000) 不推荐。您可以就地创建 table 类型。但是，如果我按照你所做的去做，你的代码中似乎有一些错误。请参阅下面的操作方法。

表格准备：

create table mn_cat_map(cat_map_id number,
                        product_num varchar2(1000),
                        catalog_type varchar2(10));
/
INSERT INTO T541682.MN_CAT_MAP (CAT_MAP_ID, PRODUCT_NUM, CATALOG_TYPE)
     VALUES (10, 'A123', 'INT');

INSERT INTO T541682.MN_CAT_MAP (CAT_MAP_ID, PRODUCT_NUM, CATALOG_TYPE)
     VALUES (2, 'B121', '2Wheer');

INSERT INTO T541682.MN_CAT_MAP (CAT_MAP_ID, PRODUCT_NUM, CATALOG_TYPE)
     VALUES (3, 'C645', '4Wheer');

COMMIT;

create or replace TYPE VARCHAR_ARRAY AS VARRAY(1000000) OF VARCHAR2(1000);
/
create or replace TYPE NUMBER_ARRAY AS VARRAY(1000000) OF NUMBER;
/

代码：阅读内联解释性注释

CREATE OR REPLACE FUNCTION GET_PRODUCT_ID_ARR (V_PRODUCT_NUM_ARR  VARCHAR_ARRAY)
   RETURN NUMBER_ARRAY
IS
   product_id_list   number_array := number_array ();

   CURSOR c1(tbl_list VARCHAR_ARRAY)
   IS
      SELECT cat_map_id
        FROM mn_cat_map
       WHERE product_num  in (select column_value from table(tbl_list)) ---Checking if the item exists in the table with passed collection 
       AND catalog_type = 'INT';

   v_output     NUMBER:= 0;
BEGIN

    --not opening cursor and am not looking for processing any records.
   --OPEN c1(V_PRODUCT_NUM_ARR);

   --passing the input varray to the cursor.
   for i in c1(V_PRODUCT_NUM_ARR)
   loop

    v_output:=v_output + 1;

    product_id_list.extend;

    product_id_list(product_id_list.COUNT):= i.cat_map_id;

     DBMS_OUTPUT.put_line('Product (' || v_output || '):' ||product_id_list(product_id_list.COUNT));


   end loop;

   RETURN product_id_list;
END;
/

执行：

SQL> select GET_PRODUCT_ID_ARR(VARCHAR_ARRAY('A123','B121','C645')) COl1 from dual;

COL1
--------------------------------------------------------------------------------
NUMBER_ARRAY(10)

Product (1):10

PL/SQL: ORA-00932: 数据类型不一致: 预期得到 NUMBER USER_NAME.VARCHAR_ARRAY

PL/SQL: ORA-00932: inconsistent datatypes: expected NUMBER got USER_NAME.VARCHAR_ARRAY

plsql

function

varray