将带有系列名称的数据标签添加到气泡图中

Question

我有一个宏可以在气泡图中添加数据标签。此代码提供 Y 轴的值。

我想改为显示 SeriesName。

Sub AddDataLabels()

Dim bubbleChart As ChartObject
Dim mySrs As Series
Dim myPts As Points

With ActiveSheet
    For Each bubbleChart In .ChartObjects
        For Each mySrs In bubbleChart.Chart.SeriesCollection
            Set myPts = mySrs.Points
            myPts(myPts.Count).ApplyDataLabels Type:=xlShowValue
        Next
    Next
End With

End Sub

我试过改变

myPts(myPts.Count).ApplyDataLabels Type:=xlShowValue

进入：

myPts(myPts.Count).ApplyDataLabels Type:=xlShowSeriesName

它给了我

'Invalid procedure call or argument'

如何更改代码以显示 SeriesName 而不是 Y 轴值？

截图

Answer 1

这对你有用吗？

bubbleChart.ApplyDataLabels xlDataLabelsShowLabel

Answer 2

在你的代码里面添加下面我的代码中的With语句，里面的参数可以根据自己的需要调整。

在下面的代码中，图表 Daralabels 将显示 SeriesName，但不会显示类别或值。

Sub AddDataLabels()

Dim bubbleChart As ChartObject
Dim mySrs As Series
Dim myPts As Points

With ActiveSheet
    For Each bubbleChart In .ChartObjects
        For Each mySrs In bubbleChart.Chart.SeriesCollection
            Set myPts = mySrs.Points

            myPts(myPts.Count).ApplyDataLabels

            With myPts(myPts.Count).DataLabel
                .ShowSeriesName = True
                .ShowCategoryName = False
                .ShowValue = False
                ' optional parameters
                .Orientation = 0
                .Font.Size = 10
                .Font.Bold = True
            End With

        Next
    Next
End With

End Sub

将带有系列名称的数据标签添加到气泡图中

Adding data labels with series name to bubble chart

excel

vba

bubble-chart