如何在 groovy 中实现 java.util.Map 的 class 上使用 propertyMissing

Question

我理解 we cannot access Map properties the same way we access them in other classes，因为能够在 groovy 中使用点符号获取地图键。

现在，对于实现 java.util.Map 的 class，有没有办法仍然受益于使用 propertyMissing 的 expando metaclass？

这是我正在尝试的：

LinkedHashMap.metaClass.methodMissing = { method, args ->
    println "Invoking ${method}"
    "Invoking ${method}"
}

LinkedHashMap.metaClass.propertyMissing = { method, args ->
    println "Accessing ${method}"
    "Accessing ${method}"
}

def foo = [:]

assert "Invoking bar" == foo.bar() // this works fine
assert "Accessing bar" == foo.bar  // this doesn't work, for obvious reasons, but I'd like to be able to do that...

我一直在尝试自定义 DelegatingMetaClasses 但没有成功...

Answer 1

不确定它是否适合您的用例，但您可以在地图上使用 Guava 和 withDefault 方法...

@Grab( 'com.google.guava:guava:16.0.1' )
import static com.google.common.base.CaseFormat.*

def map
map = [:].withDefault { key -> 
    LOWER_UNDERSCORE.to(LOWER_CAMEL, key).with { alternate ->
        map.containsKey(alternate) ? map[alternate] : null
    }
}

map.possibleSolution = 'maybe'

assert map.possible_solution == 'maybe'

这样做的一个副作用是在断言之后，映射包含两个 key:value 对：

assert map == [possibleSolution:'maybe', possible_solution:'maybe']

Answer 2

如果我理解的很好你可以提供一个自定义地图：

class CustomMap extends LinkedHashMap {

    def getAt(name) {
        println "getAt($name)"
        def r = super.getAt(name)
        r ? r : this.propertyMissing(name)
    }

    def get(name) {
        println "get($name)"
        super.get(name)
        def r = super.get(name)
        r ? r : this.propertyMissing(name)

    }
    def methodMissing(method, args) {
        println "methodMissing($method, $args)"
        "Invoking ${method}"
    }

    def propertyMissing(method) {
        println "propertyMissing($method)"
        "Accessing ${method}"
    }
}

def foo = [bar:1] as CustomMap

assert foo.bar == 1
assert foo['bar'] ==  1
assert foo.lol == 'Accessing lol'
assert foo['lol'] ==  'Accessing lol'
assert foo.bar() == 'Invoking bar'

Answer 3

我重读了 groovy Maps javadocs，我注意到有 2 个版本的 get 方法。一个接受单个参数，一个接受 2 个参数。

采用 2 的版本几乎可以完成我在这里描述的内容：如果找不到您的密钥，它 returns 将成为默认值。

我得到了想要的效果，但不是点符号，因此我只是 post 这是一个替代解决方案，以防万一有人遇到这个 post :

Map.metaClass.customGet = { key ->
    def alternate = key.replaceAll(/_\w/){ it[1].toUpperCase() }
    return delegate.get(key, delegate.get(alternate, 'Sorry...'))
}

def m = [myKey : 'Found your key']

assert 'Found your key' == m.customGet('myKey')

assert 'Found your key' == m.customGet('my_key')

assert 'Sorry...' == m.customGet('another_key')

println m

-结果-

m = [myKey:Found your key, my_key:Found your key, anotherKey:Sorry..., another_key:Sorry...]

正如 Tim 的解决方案，这导致 m 在第二个断言之后包含两个键 + 2 个具有默认值的键（抱歉...），每次我们要求初始映射中不存在的新值时...这可以通过删除具有默认值的键来解决。例如:

Map.metaClass.customGet = { key ->
    def alternate = key.replaceAll(/_\w/){ it[1].toUpperCase() }
    def ret = delegate.get(key, delegate.get(alternate, 'Sorry...'))
    if (ret == 'Sorry...') {
        delegate.remove(key)
        delegate.remove(alternate)
    }
    ret
}

请随意 comment/correct 这可能导致的任何错误...只是在这里大声思考...

如何在 groovy 中实现 java.util.Map 的 class 上使用 propertyMissing

How to use propertyMissing on a class that implements java.util.Map in groovy

groovy