无法在关于单例库的两个存在项中推断出 KnownNat

Question

我在用单例库做实验，我发现了一个我不明白的案例。

{-# LANGUAGE GADTs, StandaloneDeriving, RankNTypes, ScopedTypeVariables,
FlexibleInstances, KindSignatures, DataKinds, StandaloneDeriving  #-}

import Data.Singletons.Prelude
import Data.Singletons.TypeLits

data Foo (a :: Nat) where
 Foo :: Foo a
  deriving Show

data Thing where
  Thing :: KnownNat a => Foo a -> Thing

deriving instance Show Thing

afoo1 :: Foo 1
afoo1 = Foo 

afoo2 :: Foo 2
afoo2 = Foo 

athing :: Thing
athing = Thing afoo1

foolen :: forall n. KnownNat n => Foo n -> Integer
foolen foo =
  case sing of (SNat :: Sing n) -> natVal (Proxy :: Proxy n)


minfoo :: forall a b c. (Min a b ~ c, KnownNat c) => Foo a -> Foo b -> Integer
minfoo _ _ = 
  let c = case sing of (SNat :: Sing c) -> natVal (Proxy :: Proxy c)
  in natVal (Proxy :: Proxy c)

thinglen :: Thing -> Integer
thinglen (Thing foo) = foolen foo

我可以用它来获得两个事物中的最小值

minthing :: Thing -> Thing -> Integer
minthing (Thing foo1) (Thing foo2) = min (foolen foo1) (foolen foo2)

但为什么我不能这样做呢？

minthing' :: Thing -> Thing -> Integer
minthing' (Thing foo1) (Thing foo2) = minfoo foo1 foo2

• Could not deduce (KnownNat
                      (Data.Singletons.Prelude.Ord.Case_1627967386
                         a
                         a1
                         (Data.Singletons.Prelude.Ord.Case_1627967254
                            a a1 (GHC.TypeLits.CmpNat a a1))))

Answer 1

你需要做一些定理证明来检查给定 KnownNat a 和 KnownNat b 你可以得到 KnownNat (Min a b)。可能的解决方案：

import Data.Constraint

(...)

theorem :: forall a b. (KnownNat a, KnownNat b) =>
           Sing a -> Sing b -> Dict (KnownNat (Min a b))
theorem sa sb = case sCompare sa sb of
  SLT -> Dict
  SEQ -> Dict
  SGT -> Dict

fooSing :: forall a. KnownNat a => Foo a -> Sing a
fooSing _ = sing

minthing' :: Thing -> Thing -> Integer
minthing' (Thing foo1) (Thing foo2) =
  case theorem (fooSing foo1) (fooSing foo2) of
    Dict -> minfoo foo1 foo2

Answer 2

我觉得 user3237465 的评论需要永垂不朽，因为它删除了约束库依赖性，而且非常简洁。

minthing' :: Thing -> Thing -> Integer
minthing' (Thing foo1) (Thing foo2) =
  theorem (fooSing foo1) (fooSing foo2) $ minfoo foo1 foo2
  where
    fooSing :: KnownNat a => Foo a -> Sing a
    fooSing = const sing

theorem :: forall a b c. (KnownNat a, KnownNat b) =>
           Sing a -> Sing b -> (KnownNat (Min a b) => c) -> c
theorem sa sb c = case sCompare sa sb of
  SLT -> c
  SEQ -> c
  SGT -> c

无法在关于单例库的两个存在项中推断出 KnownNat

Could not deduce KnownNat in two existentials with respect to the singletons library

haskell

dependent-type

existential-type