Delphi XE4 IDE，如何始终隐藏对象检查器的底部窗格

Question

位于对象检查器底部的两个窗格根本没有用，它不必要地占用屏幕空间，如下面的屏幕截图所示。如何在重新启动 IDE 后禁用这两个窗格？内置选项或第三方插件对我来说没问题。谢谢。

Answer 1

下面的 XE4 代码显示了如何隐藏要删除的项目：它们是实例类 THotCommands 和 TDescriptionPane.

更新这个答案的原始版本需要一个包，包括一个加载项表单和一个按钮来刷新对象检查器以隐藏这两个不需要的物品。在下面的代码中，我已经完全删除了表单，并且项目的隐藏现在应该是完全自动的。为此，我将之前的 IDENotifier 替换为 DesignNotification 对象并使用其 SelectionChanged 事件调用隐藏 THotCommands 和 TDescriptionPane 控件的代码。 TDesignNotification 在 DesignIntf.Pas

中实现 IDesignNotification 接口

事实证明对于让隐藏过程自动工作至关重要的另一个细节是将 THotCommands 和 TDescriptionPane 控件的 Height 设置为 0，因为在 OI 中的组件选择更改后，IDE 似乎将其 Visible 属性重置为 True。幸运的是，无论执行什么代码，都不会将它们的高度重置为非零值。

显然，要使用您将包含代码的单元添加到包 (.Dpk) 文件中，然后在 IDE.

中编译并安装包

代码：

interface

uses
  [...]ToolsApi, DesignIntf;

type
  TDesignNotification = class(TInterfacedObject, IDesignNotification)
    procedure ItemDeleted(const ADesigner: IDesigner; AItem: TPersistent);
    procedure ItemInserted(const ADesigner: IDesigner; AItem: TPersistent);
    procedure ItemsModified(const ADesigner: IDesigner);
    procedure SelectionChanged(const ADesigner: IDesigner;
      const ASelection: IDesignerSelections);
    procedure DesignerOpened(const ADesigner: IDesigner; AResurrecting: Boolean);
    procedure DesignerClosed(const ADesigner: IDesigner; AGoingDormant: Boolean);
    constructor Create;
    destructor Destroy; override;
  private
    procedure HideItems;
    procedure HideFormItems(Form: TForm);
  end;

var
  DesignNotification : TDesignNotification;

implementation

procedure SetUp;
begin
  DesignNotification := TDesignNotification.Create;
  RegisterDesignNotification(DesignNotification);
end;

constructor TDesignNotification.Create;
begin
  inherited Create;
end;

procedure TDesignNotification.DesignerClosed(const ADesigner: IDesigner;
  AGoingDormant: Boolean);
begin

end;

procedure TDesignNotification.HideFormItems(Form : TForm);
var
  j,
  l : Integer;
  Panel : TPanel;
  C : TComponent;
  HideCount : Integer;

  procedure HideControl(AControl : TControl);
  begin
    AControl.Height := 0;  //  This is necessary because the IDE seems to reset
    //  Visible to True when the Object Inspector is refreshed.
    AControl.Visible := False;
  end;

begin
  HideCount := 0;
  for j := 0 to Form.ComponentCount - 1 do begin
    C := Form.Components[j];
    if C is TPanel then begin
      Panel := TPanel(C);
      for l := 0 to Panel.ControlCount - 1 do begin
        if CompareText(Panel.Controls[l].ClassName, 'TDescriptionPane') = 0 then begin
          HideControl(Panel.Controls[l]);
          Inc(HideCount);
        end
        else
          if CompareText(Panel.Controls[l].ClassName, 'THotCommands') = 0 then begin
            HideControl(Panel.Controls[l]);
            Inc(HideCount);
          end;
        if HideCount >= 2 then  //  we're done
          exit;
      end;
    end;
  end;
end;

procedure TDesignNotification.HideItems;
var
  i : Integer;
  Form : TForm;
begin
  for i := 0 to Screen.FormCount - 1 do begin
    Form := Screen.Forms[i];
    if CompareText(Form.ClassName, 'TPropertyInspector') = 0 then begin
      HideFormItems(Form);
      Break;
    end;
  end;
end;

procedure TDesignNotification.DesignerOpened(const ADesigner: IDesigner;
  AResurrecting: Boolean);
begin

end;

var
  DestroyCount : Integer;

destructor TDesignNotification.Destroy;
begin
  Inc(DestroyCount);
  inherited;
end;

procedure TDesignNotification.ItemDeleted(const ADesigner: IDesigner;
  AItem: TPersistent);
begin

end;

procedure TDesignNotification.ItemInserted(const ADesigner: IDesigner;
  AItem: TPersistent);
begin

end;

procedure TDesignNotification.ItemsModified(const ADesigner: IDesigner);
begin

end;

procedure TDesignNotification.SelectionChanged(const ADesigner: IDesigner;
  const ASelection: IDesignerSelections);
var
  C : TComponent;
begin
  //  This can get called with ADesigner = Nil
  if ADesigner = Nil then
    exit;
  C := ADesigner.Root;
  if C <> Nil then begin
    HideItems;
  end
end;

initialization
  SetUp;
finalization
  if DesignNotification <> Nil then begin
    UnRegisterDesignNotification(DesignNotification);
  end;
end.

Delphi XE4 IDE，如何始终隐藏对象检查器的底部窗格

Delphi XE4 IDE, how to always hide the bottom panes of the Object Inspector

delphi

delphi-xe4

delphi-ide