从 Json 生成谓词

Question

我在 Asp.Net 完成了一个 WEB API，returns 在 JSON 有一些兴趣点。在序言中，我通过这样做获得它：

poi(X):- http_client:http_get('http://localhost:XXXXX/api/PontosInteresse',X,[]).

这 returns 类似的东西：

X = '[{"ID":1,"nome":"teste","descricao":"gfds","tempoEstimado":21,"acessibilidade":1,"localID":1,"local":{"ID":1,"nome":"porto","latitude":"21","longitude":"-21","ApplicationUserID":null},"categoriaID":1,"categoria":{"ID":1,"nome":"cultura","ApplicationUserID":null},"hashtags":null,"ApplicationUserID":null},{"ID":2,"nome":"teste2","descricao":"qweqwe","tempoEstimado":13,"acessibilidade":1,"localID":1,"local":{"ID":1,"nome":"porto","latitude":"21","longitude":"-21","ApplicationUserID":null},"categoriaID":1,"categoria":{"ID":1,"nome":"cultura","ApplicationUserID":null},"hashtags":null,"ApplicationUserID":null},{"ID":3,"nome":"teste3","descricao":"fgdfg","tempoEstimado":0,"acessibilidade":0,"localID":1,"local":{"ID":1,"nome":"porto","latitude":"21","longitude":"-21","ApplicationUserID":null},"categoriaID":1,"categoria":{"ID":1,"nome":"cultura","ApplicationUserID":null},"hashtags":null,"ApplicationUserID":null}]'.

我怎样才能将其转换为一堆谓词，形式如下：

poi(ID, Nome, Descricao, TempoEstimado, Acessibilidade, LocalId).
local(ID, Nome, Latitude, Longitude).

Answer 1

如何访问非类型内容的示例：

:- use_module(library(http/json)).

tj :-   X = '[{"ID":1,"nome":"teste","descricao":"gfds","tempoEstimado":21,"acessibilidade":1,"localID":1,"local":{"ID":1,"nome":"porto","latitude":"21","longitude":"-21","ApplicationUserID":null},"categoriaID":1,"categoria":{"ID":1,"nome":"cultura","ApplicationUserID":null},"hashtags":null,"ApplicationUserID":null},{"ID":2,"nome":"teste2","descricao":"qweqwe","tempoEstimado":13,"acessibilidade":1,"localID":1,"local":{"ID":1,"nome":"porto","latitude":"21","longitude":"-21","ApplicationUserID":null},"categoriaID":1,"categoria":{"ID":1,"nome":"cultura","ApplicationUserID":null},"hashtags":null,"ApplicationUserID":null},{"ID":3,"nome":"teste3","descricao":"fgdfg","tempoEstimado":0,"acessibilidade":0,"localID":1,"local":{"ID":1,"nome":"porto","latitude":"21","longitude":"-21","ApplicationUserID":null},"categoriaID":1,"categoria":{"ID":1,"nome":"cultura","ApplicationUserID":null},"hashtags":null,"ApplicationUserID":null}]',
    open_any(string(X), read, S, Close, []),
    json_read(S, T),
    Close,
    maplist(convert, T, C),
    maplist(writeln, C).

convert(json(L),
    poi(ID, Nome, Descricao, TempoEstimado, Acessibilidade, LocalId)
    / local(IDLoc, NomeLoc, Latitude, Longitude)
) :-
    maplist({L}/[F,V]>>memberchk(F=V, L),
        ['ID', nome, descricao, tempoEstimado, acessibilidade, localID],
        [ID, Nome, Descricao, TempoEstimado, Acessibilidade, LocalId]),
    memberchk(local=json(LL), L),
    maplist({LL}/[F,V]>>memberchk(F=V, LL),
        ['ID', nome, latitude, longitude],
        [IDLoc, NomeLoc, Latitude, Longitude]).

产生

poi(1,teste,gfds,21,1,1)/local(1,porto,21,-21)
poi(2,teste2,qweqwe,13,1,1)/local(1,porto,21,-21)
poi(3,teste3,fgdfg,0,0,1)/local(1,porto,21,-21)

编辑

这是避免强大library(yall)

的等效代码

convert(json(L),
    poi(ID, Nome, Descricao, TempoEstimado, Acessibilidade, LocalId)
    / local(IDLoc, NomeLoc, Latitude, Longitude)
) :-
    maplist(field_value(L),
        ['ID', nome, descricao, tempoEstimado, acessibilidade, localID],
        [ID, Nome, Descricao, TempoEstimado, Acessibilidade, LocalId]),
    memberchk(local=json(LL), L),
    maplist(field_value(LL),
        ['ID', nome, latitude, longitude],
        [IDLoc, NomeLoc, Latitude, Longitude]).

field_value(Fields, Field, Value) :-
    memberchk(Field=Value, Fields).

从 Json 生成谓词

Generate predicates from Json

asp.net

json

asp.net-web-api

prolog

swi-prolog