从一个文件中复制选定的行并将这些行插入到选定行之后的另一个文件中

Question

这是我的问题假设我有一个文件 file1.txt 内容：

abc.. 
def.. 
ghi.. 
def..

和第二个文件 file2.txt，内容为：

xxx..
yyy..
zzz..

现在我想将 file1.txt 中以 "def" 开头的所有行复制到 file2.txt 并附加在 file2.txt[=20 中的 "yyy..." 行之后=]

预期输出：

xxx...
yyy...
def...
def...
zzz...

我是 perl 的新手，我尝试为此编写简单的代码，但最终只在文件末尾附加了输出

#!/usr/local/bin/perl -w 
use strict; 
use warnings;
use vars qw($filecontent $total);
my $file1 = "file1.txt";
open(FILE1, $file1) || die "couldn't open the file!";
open(FILE2, '>>file2.txt') || die "couldn't open the file!";
  while($filecontent = <FILE1>){
    if ( $filecontent =~ /def/ ) {
      chomp($filecontent);
       print FILE2 $filecontent ."\n";
      #print FILE2 $filecontent ."\n" if $filecontent =~/yyy/;
    }  
  } 
 close (FILE1); 
 close (FILE2);

perl 程序的输出是

xxx...
yyy...
zzz...
def...
def...

Answer 1

我会使用临时文件。

读取并打印 FILE2 中的所有行（临时），直到您点击 "yyy"
从 FILE1
读取并打印（临时）FILE2 的其余部分
将临时文件重命名为 FILE2

use strict; 
use warnings;

my $file1 = "file1.txt";
my $file2 = "file2.txt";
my $file3 = "file3.txt";

open(FILE1, '<', $file1) or die "couldn't open the file!";
open(FILE2, '<', $file2) or die "couldn't open the file!";
open(FILE3, '>', $file3) or die "couldn't open temp file";

while (<FILE2>) {
  print FILE3;
  if (/^yyy/) {
    last;
  }
}

while (<FILE1>) {
  if (/^def/) {
    print FILE3;
  }
}

while (<FILE2>) {
  print FILE3;
}

close (FILE1); 
close (FILE2);
close (FILE3);

rename($file3, $file2) or die "unable to rename temp file";

Answer 2

执行此操作的最简单方法是使用 Tie::File 模块，它允许您将文件作为简单的字符串数组访问。

我还使用了 List::MoreUtils 中的 first_index 来查找插入记录的位置。

use strict;
use warnings;

use Tie::File;
use List::MoreUtils qw/ first_index /;

tie my @file1, 'Tie::File', 'file1.txt' or die $!;
tie my @file2, 'Tie::File', 'file2.txt' or die $!;

my $insert = first_index { /^yyy/ } @file2;

for (@file1) {
  if ( /^def/ ) {
    splice @file2, ++$insert, 0, $_;
  }
}

输出 (file2.txt)

xxx..
yyy..
def.. 
def..
zzz..

您的测试数据没有涵盖它，但是 file1.txt 中的记录按它们出现的顺序插入到 file2.txt 中。

Answer 3

您可能想尝试 IO::All 模块：

use IO::All;
my ($f1, $f2, $i) = (io('file1.txt'), io('file2.txt'), 1);
for (@$f2) {
    splice(@$f2, $i, 0, grep /^def/, @$f1), last
        if /^yyy/;
    $i++;
}

从一个文件中复制选定的行并将这些行插入到选定行之后的另一个文件中

Copy selected lines from one file and insert those lines in another file after selected line

perl

预期输出：