批处理文件以删除 csv 中的列

Question

我编写这段代码是为了从 csv 文件中删除一列。

@echo off
setlocal enableextensions enabledelayedexpansion
type nul > tmp.txt
SET /A COUNT=0
for /F "tokens=*" %%A in (d.csv) do (
    set LINE="%%A"
    set /A COUNT+=1
    for /F "tokens=1,2,3,4,5,6,7,8,* delims=," %%a in (!LINE!) do (
        set row[0]=%%a
        set row[1]=%%b
        set row[2]=%%c
        set row[3]=%%d
        set row[4]=%%e
        set row[5]=%%f
        set row[6]=%%g
        set row[7]=%%h
)       

    echo !row[0]!,!row[2]!,!row[3]!,!row[4]!,!row[5]!,!row[6]! >>tmp.txt
        echo.
)
endlocal



Test file:
A1,B1,C1,D1,la la,,1
A2,B2,C2,D2, ,fef 3,
A3,B3,C3,D3,be be ,bo,bo 1
A4,B4,C4,D4,tu tu,tu 7,881

Output file:
A1,C1,D1,la la,1, 
A2,C2,D2, ,fef 3, 
A3,C3,D3,be be ,bo,bo 1 
A4,C4,D4,tu tu,tu 7,881

我不明白为什么在第一行的输出文件中删除了 , 并在末尾添加了 ,。另外我想知道是否有更好的方法来做到这一点。谢谢！

Answer 1

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
(
 FOR /f "delims=" %%a IN (q29441490.txt) DO (
  SET "line=%%a"
  SET "line=!line:,= , !"
  FOR /f "tokens=1,2*delims=," %%p IN ("!line!") DO (
   SET "line=%%p,%%r"
   SET "line=!line: , =,!"
   ECHO(!line!
  )
 )
)>u:\newfile.txt

GOTO :EOF

我使用了一个名为 q29441490.txt 的文件，其中包含您的数据用于我的测试。

产生 u:\newfile.txt

标记之间的分隔符是定界符序列，因此,,被视为一个分隔符，因此字段看起来移动了一位。

抓取每一行，将每个 , 替换为 , 标记化（你没有明确说明，但你似乎想删除第二列）所以 %%q 得到第一列和 %%r 第二列之后的行的其余部分。连接这些，插入逗号，然后反转替换。

如果要删除另一列，则应指定不同的 tokens 元素，并且需要调整行的重组。

批处理文件以删除 csv 中的列

batch file to remove a column in csv

excel

optimization

performance

batch-file

batch-processing