vba 将周数（和年份）转换为日期？

Question

我在单元格 C13 中有一个周数，在单元格 C14 中有一个年。

我正在使用以下公式将其转换为该周的星期四 数字的日期：

=DATE(C14,1,-6)-WEEKDAY(DATE(C14,1,3))+C13*7

我如何使用 VBA 做同样的事情？

Answer 1

对于特定年份，你可以这样做：

DateAdd("ww", WeekNumber - 1, DateSerial(2017, 1, 5))

并对其进行测试：

Debug.Print Format(DateAdd("ww", WeekNumber - 1, DateSerial(YearNumber, 1, 5)), "ddd d MMM yy")

如果其他人正在调查此问题并且 不想在星期四或 2017 年不工作 :

根据您的需要更改 5！
或者使用下面的函数GetDayFromWeekNumber

测试代码：

Sub test()
    Debug.Print Format(GetDayFromWeekNumber(2017, 1, 4), "ddd d MMM yyyy")
End Sub

和通用函数GetDayFromWeekNumber：

Public Function GetDayFromWeekNumber(InYear As Integer, _
                WeekNumber As Integer, _
                Optional DayInWeek1Monday7Sunday As Integer = 1) As Date
    Dim i As Integer: i = 1
    If DayInWeek1Monday7Sunday < 1 Or DayInWeek1Monday7Sunday > 7 Then
        MsgBox "Please input between 1 and 7 for the argument :" & vbCrLf & _
                "DayInWeek1Monday7Sunday!", vbOKOnly + vbCritical
        'Function will return 30/12/1899 if you don't use a good DayInWeek1Monday7Sunday
        Exit Function
    Else
    End If

    Do While Weekday(DateSerial(InYear, 1, i), vbMonday) <> DayInWeek1Monday7Sunday
        i = i + 1
    Loop

    GetDayFromWeekNumber = DateAdd("ww", WeekNumber - 1, DateSerial(InYear, 1, i))
End Function

Answer 2

考虑到一周的第一天是星期日，它工作得很好：

Function fnDateFromWeek(ByVal iYear As Integer, ByVal iWeek As Integer, ByVal iWeekDday As Integer)

        fnDateFromWeek = DateSerial(iYear, 1, ((iWeek - 1) * 7) + iWeekDday - Weekday(DateSerial(iYear, 1, 1)) + 1)

End Function

你必须将你想要哪一天作为第三个参数。星期四是第 5 天。感谢这些人：http://www.dreamincode.net/forums/topic/111464-calculate-date-from-year-weeknr-and-daynumber/

Answer 3

作为附加选项，对于那些使用 ISO weeknumber 系统的人来说，一年中的第 1 周是一年中包含四天的第一周（或包含日历年第一个星期四的那一周，以及一周的第一天是星期天。

DOW 是表示星期几的可选参数。它将默认为星期四，并且由于我们使用的是 ISO 周数系统，因此应始终属于当年。

Option Explicit
Function WNtoDate(WN As Long, YR As Long, Optional DOW As Long = 5) As Date
    'DOW:  1=SUN, 2=MON, etc
    Dim DY1 As Date
    Dim Wk1DT1 As Date
    Dim I As Long

DY1 = DateSerial(YR, 1, 1)
'Use ISO weeknumber system
I = DatePart("ww", DY1, vbSunday, vbFirstFourDays)

'Sunday of Week 1
Wk1DT1 = DateAdd("d", -Weekday(DY1), DY1 + 1 + IIf(I > 1, 7, 0))

WNtoDate = DateAdd("ww", WN - 1, Wk1DT1) + DOW - 1

End Function

vba 将周数（和年份）转换为日期？

vba convert week number (and year) to date?

excel

vba

formula