如何根据PKG_CHECK_MODULES结果定义AM_CONDITIONAL和AC_DEFINE？

Question

我正在尝试编写一个 configure.ac 文件来完成这些任务：

configure 脚本应该接受一个 --with-libuv 参数。
变量 with_libuv 应设置为 yes、no 或 check（默认值为 check当命令行上没有传递任何内容时）。
当 with_libuv == "yes" 时，应该对 libuv >= 1.9.0 进行强制性 PKG_CHECK_MODULES 检查，并在成功时设置 HAVE_LIBUV = 1（错误 configure 应该中止）。
当with_libuv == "no"什么都不检查时，
当 with_libuv == "false" 一个可选的 PKG_CHECK_MODULES 检查（对于与 3. 中相同的库）应该完成并且 HAVE_LIBUV 应该设置为 0 或 1 相应地。
如果with_libuv != "no" && HAVE_LIBUV == 1 AC_DEFINE应该设置-DUSE_LIBUV并且AM_CONDITIONAL应该设置USE_LIBUV作为automake的条件。
如果不是 with_libuv != "no" && HAVE_LIBUV == 1，则不应设置预处理器指令，并且 AM_CONDITIONAL 应设置为 0。

我已经知道如何执行第 1-5 步，但我在第 6 步和第 7 步上苦苦挣扎。

这是我目前的尝试：

AC_INIT(
  [mumble-pluginbot-plusplus],
  [0.5],
  [https://github.com/promi/mumble-pluginbot-plusplus/issues],
  [],
  [https://github.com/promi/mumble-pluginbot-plusplus])

AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([foreign])
AM_SILENT_RULES([yes])

AC_PROG_CXX
LT_INIT

# Make sure that pkg-config is installed!
# The PKG_CHECK_MODULES macro prints a horrible error message when
# pkg-config is not installed at autogen time.                   
#
# It is also required when the first PKG_CHECK_MODULES is inside a conditional
PKG_PROG_PKG_CONFIG

PKG_CHECK_MODULES(OPUS, [opus >= 1.1])
PKG_CHECK_MODULES(OPENSSL, [openssl])
PKG_CHECK_MODULES(PROTOBUF, [protobuf])
PKG_CHECK_MODULES(MPDCLIENT, [libmpdclient])

AC_ARG_WITH(
  [libuv],
  [AS_HELP_STRING([--with-libuv], [support efficient MPD status polling @<:@default=check@:>@])],
  [],
  [with_libuv=check])

# if     --with-libuv    -> it must be installed
# elseif --without-libuv -> do nothing
# else                   -> check whether it is installed
AS_CASE(
  ["$with_libuv"],
  [yes], [PKG_CHECK_MODULES(UV, [libuv >= 1.9.0], [HAVE_LIBUV=1])],
  [no],  [],
         [PKG_CHECK_MODULES(UV, [libuv >= 1.9.0], [HAVE_LIBUV=1], [HAVE_LIBUV=0])])

if test "$with_libuv" != no -a "x$HAVE_LIBUV" -eq x1; then
   AM_CONDITIONAL([USE_LIBUV], [1])
   AC_DEFINE([USE_LIBUV], [1], [Define when libuv should be used.])
else
   AM_CONDITIONAL([USE_LIBUV], [0])
fi

#AC_CONFIG_HEADERS([src/config.h])
AC_CONFIG_FILES([Makefile])

AC_OUTPUT

有问题的部分是：

if test "$with_libuv" != no -a "x$HAVE_LIBUV" -eq x1; then
   AM_CONDITIONAL([USE_LIBUV], [1])
   AC_DEFINE([USE_LIBUV], [1], [Define when libuv should be used.])
else
   AM_CONDITIONAL([USE_LIBUV], [0])
fi

以下是配置输出的摘录：

checking pkg-config is at least version 0.9.0... yes
checking for OPUS... yes
checking for OPENSSL... yes
checking for PROTOBUF... yes
checking for MPDCLIENT... yes
checking for UV... yes
./configure: line 16467: test: x1: integer expression expected
./configure: line 16480: 0: command not found
checking that generated files are newer than configure... done

如何以实际可行的方式实施步骤 6 和 7？

Answer 1

我认为你应该使用 = 而不是 -eq。 -eq 是整数之间的关系 - x1 不是整数！

if test "$with_libuv" != no -a "x$HAVE_LIBUV" -eq x1; then

替换为

if test "$with_libuv" != no -a "x$HAVE_LIBUV" = x1; then

Answer 2

这应该可以解决问题：

if test "$with_libuv" != no -a "x$HAVE_LIBUV" == x1; then
   AC_DEFINE([USE_LIBUV], [1], [Define when libuv should be used.])
fi
AM_CONDITIONAL([USE_LIBUV], [test "$with_libuv" != no -a "x$HAVE_LIBUV" == x1])

有点难看，因为测试执行了两次，不过好像没问题。

Answer 3

当 yes 失败时，您并未中止（第 3 步）。 AM_CONDITIONAL should always be run. Step 6 says -DUSE_LIBUV, but your existing code will add -DUSE_LIBUV=1 to DEFS. Portable shell scripting considers test -a broken，所以你不应该使用它。您的 no 案例等同于搜索失败的 check（或 false）案例。

AS_CASE(
   ["$with_libuv"],
   [yes], [PKG_CHECK_MODULES(UV, [libuv >= 1.9.0], [HAVE_LIBUV=1],
                            [AC_MSG_ERROR("libuv >= 1.9.0 is not installed")])],
   [no],  [HAVE_LIBUV=0],
   [PKG_CHECK_MODULES(UV, [libuv >= 1.9.0], [HAVE_LIBUV=1],[HAVE_LIBUV=0])])

AS_IF([test "x$HAVE_LIBUV" = x1], [AC_DEFINE([USE_LIBUV])])
AM_CONDITIONAL([USE_LIBUV], [test "x$HAVE_LIBUV" = x1])

如何根据PKG_CHECK_MODULES结果定义AM_CONDITIONAL和AC_DEFINE？

How to define AM_CONDITIONAL and AC_DEFINE based on PKG_CHECK_MODULES result?

automake

autoconf

pkg-config

autotools

sh