T-SQL - 在两个特定单词之后拆分下一个单词

Question

假设我有以下字符串： "Select * From table_1 INNER JOIN table_2 ON table_1.A = table_2.B"

我想提取语句的两个表，以便得到： table_1; table_2.

基本上我需要获取字符串 From 和 Join 之后的下一个单词。我正在尝试以下查询：

DECLARE @StaffName nvarchar(4000)
SET @StaffName = 'Select * From table_1 INNER JOIN table_2 ON table_1.A = table_2.B'

SELECT SUBSTRING
  (
    @StaffName,  
        CHARINDEX('From', @StaffName), 
    CHARINDEX(' ', SUBSTRING(@StaffName, CHARINDEX(' ', @StaffName), 255))
  ) ,
    SUBSTRING(@StaffName, CHARINDEX('From ', @StaffName) + 5, LEN(@StaffName))
    ,
    SUBSTRING(@StaffName, CHARINDEX('From ', @StaffName) + 5, LEN(@StaffName))
    ,
    RIGHT(@StaffName,LEN(@StaffName)-CHARINDEX('From ',@StaffName))

但我没有得到我想要的:(

谁能帮帮我？

非常感谢！

Answer 1

使用 left()、right(), 和 charindex() 的组合：

declare @str varchar(256) = 'Select * From table_1 INNER JOIN table_2 ON table_1.A = table_2.B';

select 
    tbl1 = left(right(@str,len(@str)-charindex(' From ',@str)-5)
        ,charindex(' ',right(@str,len(@str)-charindex(' From ',@str)-5))-1
       )
  , tbl2 = left(right(@str,len(@str)-charindex(' Join ',@str)-5)
        ,charindex(' ',right(@str,len(@str)-charindex(' Join ',@str)-5))-1
       )

rextester 演示：http://rextester.com/WOO86939

returns:

+---------+---------+
|  tbl1   |  tbl2   |
+---------+---------+
| table_1 | table_2 |
+---------+---------+

Answer 2

查看 SQLZim 的完全有效 (+1) 的答案，让我意识到我已经厌倦了提取部分字符串。因此，我修改了我的解析函数以接受两个多字符定界符。因此，如果您对 UDF 开放，请考虑以下事项：

旁注：作为 Table-Valued-Function，很容易合并到 CROSS APPLY 中或作为单个查询

根据您的具体要求，我们正在寻找 FROM 和 ON

的关键词

Declare @String varchar(max) = 'Select * From table_1 INNER JOIN table_2 ON table_1.A = table_2.B'
Select Table1 = left(RetVal,charindex(' ',RetVal+' ')-1)
      ,Table2 = right(RetVal,charindex(' ',reverse(RetVal)+' ')-1)
 From [dbo].[udf-Str-Extract] (@String,' from ',' on ')

Returns

Table1  Table2
table_1 table_2

一个通用示例：

假设我们正在寻找 {}

之间的值

Declare @String varchar(max) = 'co-101{12345},co-513{22578}'
Select * From [dbo].[udf-Str-Extract] (@String,'{','}')

Returns

RetSeq  RetPos  RetLen  RetVal
1       8       5       12345
2       22      5       22578

另一个通用示例

Declare @String varchar(max) = '<root><firstmame>John</firstname><lastname>Cappelletti</lastname><phone>(401) 555-1212</phone></root>'
Select * From [dbo].[udf-Str-Extract] (@String,'>','<')

Returns

RetSeq  RetPos  RetLen  RetVal
1       18      4       John
2       44      11      Cappelletti
3       73      14      (401) 555-1212

感兴趣的 UDF

CREATE FUNCTION [dbo].[udf-Str-Extract] (@String varchar(max),@Delimiter1 varchar(100),@Delimiter2 varchar(100))
Returns Table 
As
Return (  

with   cte1(N)   As (Select 1 From (Values(1),(1),(1),(1),(1),(1),(1),(1),(1),(1)) N(N)),
       cte2(N)   As (Select Top (IsNull(DataLength(@String),0)) Row_Number() over (Order By (Select NULL)) From (Select N=1 From cte1 N1,cte1 N2,cte1 N3,cte1 N4,cte1 N5,cte1 N6) A ),
       cte3(N)   As (Select 1 Union All Select t.N+DataLength(@Delimiter1) From cte2 t Where Substring(@String,t.N,DataLength(@Delimiter1)) = @Delimiter1),
       cte4(N,L) As (Select S.N,IsNull(NullIf(CharIndex(@Delimiter1,@String,s.N),0)-S.N,8000) From cte3 S)

Select RetSeq = Row_Number() over (Order By N)
      ,RetPos = N
      ,RetLen = charindex(@Delimiter2,RetVal)-1
      ,RetVal = left(RetVal,charindex(@Delimiter2,RetVal)-1)
 From (Select A.N,RetVal = ltrim(rtrim(Substring(@String, A.N, A.L))) From cte4 A ) A
 Where charindex(@Delimiter2,RetVal)>1
)
/*
Max Length of String 1MM characters

Declare @String varchar(max) = 'Dear [[FirstName]] [[LastName]], ...'
Select * From [dbo].[udf-Str-Extract] (@String,'[[',']]')
*/

T-SQL - 在两个特定单词之后拆分下一个单词

T-SQL - Split the next word after two specific words

sql

sql-server

tsql

substring

charindex