ModelSim 模拟器中的实体无输出 - VHDL

Question

我已经用 VHDL 编写了一个简单的实体来使 LED 闪烁，并试图在 ModelSim 中对其进行模拟，但在输出上没有任何转换。

这是我的 LED_Blink 实体的 HDL 文件：

Library IEEE;
use IEEE.Std_logic_1164.all;

entity LED_Blink is

generic (
    g_SYSTEM_CLOCK_PERIOD   : in time := 10 ns; -- 100 MHz clock period
    g_LED_ON_TIME           : in time := 1 sec
);

port(
    system_clock    : in Std_logic; 
    reset_fpga_L    : in Std_logic;

    led_out         : out Std_logic
);
end entity LED_Blink;

architecture RTL of LED_Blink is
    signal led_state : Std_logic;
    constant COUNTER_RELOAD_VAL : natural := g_LED_ON_TIME/g_SYSTEM_CLOCK_PERIOD;
begin
    process(reset_fpga_L, system_clock)
        variable counter : natural range 0 to COUNTER_RELOAD_VAL := COUNTER_RELOAD_VAL;
    begin
        if reset_fpga_L = '0' then
            counter := COUNTER_RELOAD_VAL;
            led_state <= '0';
        elsif rising_edge(system_clock) then
            if counter = 0 then
                led_state <= not led_state;
                counter := COUNTER_RELOAD_VAL;
            else
                counter := counter - 1;
            end if;            
        end if;

        led_out <= led_state;
    end process;
end architecture RTL;

这是我的测试台：

Library IEEE;
use IEEE.Std_logic_1164.all;

entity LED_Blink_TB is
end entity LED_Blink_TB;

architecture RTL of LED_Blink_TB is

    signal reset_fpga_L : Std_logic := '0';
    signal system_clock : Std_logic := '0';

    signal led_out      : Std_logic := '0';

begin

    G1: entity work.LED_Blink(RTL) port map(reset_fpga_L, system_clock, led_out);

    CLK: process
    begin
        while now <= 5 sec loop
            system_clock <= not system_clock;
            wait for 5 ns;
        end loop;
        wait;
    end process CLK;

    STIM: process
    begin
        reset_fpga_L <= '0';
        wait for 100 ns;
        reset_fpga_L <= '1';
        wait for 4 sec;
        reset_fpga_L <= '0';
        wait for 50 ns;
        reset_fpga_L <= '1';
        wait;
    end process STIM;

end architecture RTL;

我不明白为什么当我在模拟器中运行我的测试台时，我在 led_out 上看不到任何转换。我已经注意将 system_clock、reset_fpga_L 和 led_out 的波形添加到跟踪视图中。您在我的代码中看到任何可能有问题的地方吗？感谢您的帮助。

Answer 1

可以使用第二种形式的测试台生成 LED_Blink 的输入取决于作为泛型提供的值：

library ieee;
use ieee.std_logic_1164.all;

entity led_blink_tb is
end entity;

architecture foo of led_blink_tb is
    constant CLK_PERIOD:    time := 100 ms;
    constant LED_ON:        time := 500 ms;
    signal clk:             std_logic := '0';
    signal reset_n:         std_logic;
    signal led:             std_logic;
begin
DUT:
    entity work.led_blink
        generic map ( CLK_PERIOD, LED_ON)
        port map (
            system_clock => clk,
            reset_fpga_l => reset_n,
            led_out => led
        );
CLOCK:
    process
    begin
        wait for CLK_PERIOD/2;
        clk <= not clk;
        if now > 2.5 sec then
            wait;
        end if;
    end process;
STIMULI:
    process
    begin
        reset_n <= '0';
        wait for CLK_PERIOD * 2;
        reset_n <= '1';
        wait;
    end process;
end architecture;

这个想法，测试台和模型都依赖于作为泛型提供的常量，使得更改参数需要更少的工作。

另请注意端口映射中的关联列表使用命名关联。

如果我们看一下原始测试台端口映射：

G1: entity work.LED_Blink(RTL) port map(reset_fpga_L, system_clock, led_out);

我们看到正式 system_clock 的第一个位置关联与实际 reset_fpga_L 相关联，而代表正式 reset_fpga_L 的第二个位置关联与实际 [=25] 相关联=].

两个实际关联的顺序相反。

ModelSim 模拟器中的实体无输出 - VHDL

No Output From Entity in ModelSim Simulator - VHDL

vhdl

modelsim